* ISRECP
*
*     LAS RUTINAS DE *ISRECP* SIRVEN PARA DESPLEGAR LA INFORMACION
*     DE UN ARCHIVO A RECONSTRUIR. SE PUEDEN USAR EN DOS CASOS, LAS
*     INSTRUCCIONES PARA HACERLO SON:
*
*     CASO A) SIEMPRE SE RECONSTRUYE EL ARCHIVO CON NOMBRE nomb:
*
*             MOVER 'nomb' A RECA-ARCHIVO
*             EJECUTA RUTINA INICIO-RECONSTRUCCION
*             OPCION DISCO nomb RECA
*             EJECUTA RUTINA DESPLEGAR-ESTADISTICAS-RECA
*
*     CASO B) SE PREGUNTA AL USUARIO SI TIENE MAS DE UN % DE USO:
*             (EL % MAXIMO DE USO SE DEFINIO EN DBD)
*
*             MOVER 'nomb' A RECA-ARCHIVO
*             OPCION DISCO nomb EXCLUSIVO RECA-POR-USO
*             EJECUTA RUTINA PREGUNTAR-RECONSTRUCCION
*             SI RECA-SE-RECONSTRUYE = 'NO' EJECUTA ...
*             OPCION DISCO nomb RECA
*             EJECUTA RUTINA DESPLEGAR-ESTADISTICAS-RECA
*         ...
*
**********************************************************************
*
RUTINA INICIO-RECONSTRUCCION
*
*     DEFINIR AREA DE RECONSTRUCCION
*
*
*     DEFINIR AREA DE PREGUNTA DE RECONSTRUCCION
*
      OPCION TERMINAL AREA 9010 /RENGLON 0 0  /POS. 2 5 /LONG. 3 70 $
       /MARCO /COLOR BLANCO BLANCO NEGRO /TIEMPO 0 0 /CAMPOS  2 3   $
       'Se reconstruye el archivo ' RECA-ARCHIVO  /VAR.
*
       RECA-INICIO = 0
       OPCION TERMINAL AREA 9010 /DESPLEGAR
       ESCRIBIR TERMINAL RECA-ARCHIVO
       RETORNO
*
***********************************************************************
*
RUTINA PREGUNTAR-RECONSTRUCCION
*
*     DEFINIR AREA DE PREGUNTA DE RECONSTRUCCION
*
      OPCION TERMINAL AREA 9011 /RENGLON 0 0  /POS. 2 5 /LONG. 3 70 $
       /MARCO /COLOR BLANCO BLANCO NEGRO /TIEMPO 0 0 /CAMPOS  2 3 $
       'El archivo ' RECA-ARCHIVO  /VAR. ' esta' RECA-POR-USO /VAR. $
       '% lleno, se reconstruye: ' RECA-SE-RECONSTRUYE /VAR. /LEC.
*
       MOVER 'NO' A RECA-SE-RECONSTRUYE
       RECA-INICIO = 1
&R     SI RECA-POR-USO <= &RECA-POR-USO-MAXIMO  EJECUTA  10
       OPCION TERMINAL AREA 9011 /DESPLEGAR
       ESCRIBIR TERMINAL RECA-ARCHIVO RECA-POR-USO
       LEER TERMINAL EJECUTA 10 RECA-SE-RECONSTRUYE
10     RETORNO
*
************************************************************************
*
RUTINA    DESPLEGAR-ESTADISTICAS-RECA
*
*     RUTINA PARA DESPLEGAR INFORMACION DE ESTADISTICAS
*     DE RECONSTRUCCION (T990) DE OPCION DISCO RECA
*
*     DEFINIR AREA DE DATOS GENERALES
*
&*
&Q RECA   SI RECA-DESPLEGAR-FH = NO
      OPCION TERMINAL AREA 9012 /RENGLON  1 1 /POS. 6 5 /LONG. 8 70 $
       /MARCO /COLOR BLANCO BLANCO NEGRO   /TIEMPO 0 0 /CAMPOS  $
       2 3 RECA-NOMBRE-EXTENDIDO /ESC. $
       3 12 RECA-NOMBRE-COMPLETO /VAR. /LONG. 56 $
       5 3 'FECHA ANTERIOR:' RECA-FECHA-ULT-ACT /VAR. $
                             RECA-HORA-ULT-ACT /VAR. $
       5 38 'FECHA NUEVA:'   RECA-FECHA-ACT /VAR. $
                             RECA-HORA-ACT /VAR. $
       7 3  RECA-TOTAL-PERDIDOS /ESC. $
       7 30 RECA-TOTAL-DUPLICADOS  /ESC. $
       7 55 RECA-ENTERADO
&F RECA
&*
&Q RECA   SI RECA-DESPLEGAR-FH = SI
      OPCION TERMINAL AREA 9012 /RENGLON  1 1 /POS. 6 5 /LONG. 8 70 $
       /MARCO /COLOR BLANCO BLANCO NEGRO   /TIEMPO 0 0 /CAMPOS  $
       3 3 RECA-NOMBRE-EXTENDIDO /ESC. $
       4 12 RECA-NOMBRE-COMPLETO /VAR. /LONG. 56 $
       6 3  RECA-TOTAL-PERDIDOS /ESC. $
       6 30 RECA-TOTAL-DUPLICADOS  /ESC. $
       6 55 RECA-ENTERADO
&F RECA
&*
&Q RECA   SI RECA-DESPLEGAR-RX = NO
*
*     DEFINIR AREA PARA RECURRENTES
*
      OPCION TERMINAL AREA 9013 /COLUMNA /POS. 15 5 /LONG. 6 70 $
       /MARCO /COLOR BLANCO BLANCO NEGRO   /CAMPOS  $
       RECA-RX /LET. RECA-X4 /VAR. RECA-NOMBRE-RX /ESC. /LONG. 30 $
       RECA-LEIDOS /ESC. RECA-BORRADOS /ESC. RECA-PERDIDOS /ESC.
&F RECA
&*
&Q RECA   SI RECA-DESPLEGAR-LLX = NO
*
*     DEFINIR AREA PARA LLAVES
*
      OPCION TERMINAL AREA 9014 /COLUMNA /POS. 15 5 /LONG. 6 70 $
       /MARCO /COLOR BLANCO BLANCO NEGRO   /CAMPOS  $
       RECA-LLX /LET. RECA-X4 /VAR. RECA-INSERTADOS /ESC. $
       RECA-DUPLICADOS /ESC.
&F RECA
&*
&Q RECA   SI RECA-DESPLEGAR-TIA = NO
*
*     DEFINIR AREA PARA VARIABLES TEXTO/IMAGEN/AUDIO
*
      OPCION TERMINAL AREA 9015 /COLUMNA /POS. 15 5 /LONG. 6 70 $
       /MARCO /COLOR BLANCO BLANCO NEGRO   /CAMPOS  $
       RECA-TIA-NOMBRE /ESC. /LONG. 24 RECA-TIA-LEIDOS /ESC. $
       RECA-TIA-PERDIDOS /ESC. RECA-TIA-LP /ESC. RECA-TIA-LM /ESC.
&F RECA
&*
*
**********************************************************************
*
*     LEER NOMBRES, FECHA Y HORA, TOTAL DE PERDIDOS Y DUPLICADOS
*
      OPCION TEMPORAL 990 /LECTURA /ASCII
      OPCION TERMINAL AREA 9012 /DESPLEGAR /SALVAR-ANTERIORES $
                                /EMPALMAR
      LEER TEMPORAL 990 EJECUTA 100 RECA-NOMBRE-COMPLETO $
      RECA-FECHA-ULT-ACT RECA-HORA-ULT-ACT $
      RECA-FECHA-ACT RECA-HORA-ACT RECA-NOMBRE-EXTENDIDO
      ESCRIBIR TERMINAL RECA-NOMBRE-EXTENDIDO RECA-NOMBRE-COMPLETO
&*
&Q RECA   SI RECA-DESPLEGAR-FH = NO
      ESCRIBIR TERMINAL RECA-FECHA-ULT-ACT RECA-HORA-ULT-ACT $
      RECA-FECHA-ACT RECA-HORA-ACT
&F RECA
&*
      LEER TEMPORAL 990 EJECUTA 100 RECA-TOTAL-PERDIDOS $
                                    RECA-TOTAL-DUPLICADOS
      ESCRIBIR TERMINAL RECA-TOTAL-PERDIDOS RECA-TOTAL-DUPLICADOS
      LEER TERMINAL EJECUTA 90 RECA-ENTERADO
*
*******************************************************************
*
*     LEER DATOS DEL DE RECURRENTES
*
&*
&Q RECA SI RECA-DESPLEGAR-RX = NO
      OPCION TERMINAL AREA 9013 /SALVAR-ANTERIORES /DESPLEGAR $
                                /EMPALMAR
      LEER TEMPORAL 990 EJECUTA 100 RECA-TOTAL-RX
10    LEER TEMPORAL 990 EJECUTA 100 RECA-RX RECA-LEIDOS $
                        RECA-BORRADOS RECA-PERDIDOS RECA-NOMBRE-RX
      MOVER 'R' A RECA-X4
      MOVER RECA-RX A RECA-X4 /AGREGAR 0
      ESCRIBIR TERMINAL RECA-X4 RECA-LEIDOS RECA-BORRADOS $
                        RECA-PERDIDOS RECA-NOMBRE-RX
      RECA-TOTAL-RX = RECA-TOTAL-RX - 1
      SI RECA-TOTAL-RX > 0 EJECUTA 10
      OPCION TERMINAL AREA 9013 /TERMINAR
&F RECA
&*
&Q RECA SI RECA-DESPLEGAR-RX = SI
      LEER TEMPORAL 990 EJECUTA 100 RECA-TOTAL-RX
10    LEER TEMPORAL 990 EJECUTA 100 RECA-RX RECA-LEIDOS $
                        RECA-BORRADOS RECA-PERDIDOS RECA-NOMBRE-RX
      RECA-TOTAL-RX = RECA-TOTAL-RX - 1
      SI RECA-TOTAL-RX > 0 EJECUTA 10
&F RECA
*
********************************************************************
*
*     LEER DATOS DEL DE LLAVES
*
&*
&Q RECA SI RECA-DESPLEGAR-LLX = NO
      OPCION TERMINAL AREA 9014 /SALVAR-ANTERIORES /DESPLEGAR $
                                /EMPALMAR
      LEER TEMPORAL 990 EJECUTA 100 RECA-TOTAL-LLX
20    LEER TEMPORAL 990 EJECUTA 100 RECA-LLX RECA-RX-LLX RECA-NIV $
                        RECA-INSERTADOS RECA-DUPLICADOS
      MOVER 'LL' A RECA-X4
      MOVER RECA-LLX A RECA-X4 /AGREGAR 0
      ESCRIBIR TERMINAL RECA-X4 RECA-INSERTADOS RECA-DUPLICADOS
      RECA-TOTAL-LLX = RECA-TOTAL-LLX - 1
      SI RECA-TOTAL-LLX > 0 EJECUTA 20
      OPCION TERMINAL AREA 9014 /TERMINAR
&F RECA
&*
&Q RECA SI RECA-DESPLEGAR-LLX = SI
      LEER TEMPORAL 990 EJECUTA 100 RECA-TOTAL-LLX
20    LEER TEMPORAL 990 EJECUTA 100 RECA-LLX RECA-RX-LLX RECA-NIV $
                        RECA-INSERTADOS RECA-DUPLICADOS
      RECA-TOTAL-LLX = RECA-TOTAL-LLX - 1
      SI RECA-TOTAL-LLX > 0 EJECUTA 20
&F RECA
*
************************************************************************
*
*     LEER DATOS DEL DE TEXTO IMAGEN AUDIO
*
&*
&Q RECA SI RECA-DESPLEGAR-TIA = NO
      LEER TEMPORAL 990 EJECUTA 100 RECA-TOTAL-TIA
      SI RECA-TOTAL-TIA = 0 EJECUTA 90
      OPCION TERMINAL AREA 9015 /SALVAR-ANTERIORES /DESPLEGAR $
                                /EMPALMAR
30    LEER TEMPORAL 990 EJECUTA 100 RECA-TIA RECA-TIA-NOMBRE $
                        RECA-TIA-LEIDOS RECA-TIA-PERDIDOS $
                        RECA-TIA-LP RECA-TIA-LM
      ESCRIBIR TERMINAL RECA-TIA-NOMBRE RECA-TIA-LEIDOS $
                        RECA-TIA-PERDIDOS RECA-TIA-LP $
                        RECA-TIA-LM
      RECA-TOTAL-TIA = RECA-TOTAL-TIA - 1
      SI RECA-TOTAL-TIA > 0 EJECUTA 30
      OPCION TERMINAL AREA 9015 /TERMINAR
&F RECA
&*
90    OPCION TERMINAL AREA 9012 /TERMINAR
      SI RECA-INICIO = 0 OPCION TERMINAL AREA 9010 /TERMINAR
      SI RECA-INICIO = 1 OPCION TERMINAL AREA 9011 /TERMINAR
      OPCION TEMPORAL 990 /BORRAR
      RETORNO
*
*     ERROR EN TEMPORAL
*
100   ERROR 'ERROR INTERNO TEMPORAL MAL FORMADO'
      SI 0 <> 0 EJECUTA RUTINA INICIO-RECONSTRUCCION
      SI 0 <> 0 EJECUTA RUTINA PREGUNTAR-RECONSTRUCCION
      FIN
