* PSDCF5
       PROGRAMA 'LISTAR AYUDAS'  DIR /COLOR AZUL AMARILLO
       DOCUMENTACION 3 0
       SI DIR-PER-TEM = ' ' EJECUTA 1
       OPCION DISCO AYUDAA DISCO DIR-PER-TEM
       OPCION DISCO AYUDAV DISCO DIR-PER-TEM
       OPCION DISCO AYUDAP DISCO DIR-PER-TEM
*
*D    ESTE PROGRAMA LISTAR LAS AYUDAS DE LOS ARCHIVOS
*D
*     DEFINIR AREA DE MENU
*
      IGUAL AREA N1 NUM
      OPCION TERMINAL AREA 1 /MENU /MARCO /POS. 3 15 /LONG. 8 50 $
      /COLOR BLANCO BLANCO NEGRO NEGRO AMARILLO AZUL BLANCO $
       /TECLAS-DE-FUNCION 1 'TERMINAR' 2 '*AYUDA' 3 'MENU' $
       /AYUDA-GLOBAL DESPLEGAR-AYUDA $
       /BN NO-E VI NO-E /CAMPOS  'Opciones de listar:' /ENC. $
      1 '*VARIABLES (AYUDAV)' 2 '*AREAS (AYUDAA)' $
      3 '*PROGRAMAS (AYUDAP)' NUM /VAR-SEL.
*
*     DEFINIR AREA DE PREGUNTA DE IMPRESION
*
      IGUAL AREA N1 NUM1
      OPCION TERMINAL AREA 2 /MENU /MARCO /POS. 12 15 /LONG. 3 50 $
      /COLOR BLANCO BLANCO NEGRO NEGRO AMARILLO AZUL BLANCO $
       /TECLAS-DE-FUNCION 1 'TERMINAR' 2 '*AYUDA' 3 'MENU' $
       /AYUDA-GLOBAL DESPLEGAR-AYUDA $
       /BN NO-E VI NO-E /CAMPOS  1 '*Desplegar' 2 '*Imprimir' $
         3 '*Borrar' NUM1 /VAR-SEL.
*
*     DEFINIR AREA DE BUSCAR
*
      OPCION TERMINAL AREA 3 /RENGLON /MARCO /POS. 16 15 /LONG. 3 50 $
      /COLOR BLANCO BLANCO NEGRO NEGRO AMARILLO AZUL BLANCO $
       /TECLAS-DE-FUNCION 1 'TERMINAR' 2 '*AYUDA' 3 'MENU' $
       /AYUDA-GLOBAL DESPLEGAR-AYUDA $
       /BN NO-E VI NO-E /CAMPOS  PAL-BUSC /BLANCOS
*
*     DESPLEGAR AREAS Y LEER SELECCION
*
1     OPCION TERMINAL AREA 1 2 3  /DESPLEGAR
      LEER TERMINAL EJECUTA 50 NUM
      SI NUM = 2 EJECUTA 20
      SI NUM = 3 EJECUTA 30
*
*     CASO DE LISTAR AYUDAV
*
      OPCION IMPRIMIR ARCHIVO BORRAR COL. 80 ENC. 2 NOM-VAR 33 INI-PRO $
            50 TEXTO-AYUDA LET. 'TEXTO DE AYUDA DE VARIABLE-PROGRAMA'
      OPCION DISCO AYUDAV INICIO-G1
11    BUSCAR DISCO AYUDAV EJECUTA 40 SEC-G1
      LEER DISCO AYUDAV NOM-VAR INI-PRO TEXTO-AYUDA
      DETALLE 2 NOM-VAR
      DETALLE 33 INI-PRO
      IMPRIMIR DETALLE 40 TEXTO-AYUDA LONG. 40
      IMPRIMIR DETALLE 1 '0' 2 80'* / 1 '0'
      EJECUTA 11
*
*     CASO DE LISTAR AYUDAA
*
20    OPCION IMPRIMIR ARCHIVO BORRAR COL. 80 $
       ENC. 10 NUM-AREA 20 INI-PRO 40 TEXTO-AYUDA  $
        LET. 'TEXTO DE AYUDA DE AREA-PROGRAMA'
      OPCION DISCO AYUDAA INICIO-G1
21    BUSCAR DISCO AYUDAA EJECUTA 40 SEC-G1
      LEER DISCO AYUDAA NUM-AREA INI-PRO TEXTO-AYUDA
      DETALLE 10 NUM-AREA
      DETALLE 20 INI-PRO
      IMPRIMIR DETALLE 40 TEXTO-AYUDA LONG. 40
      IMPRIMIR DETALLE 1 '0' 2 80'* / 1 '0'
      EJECUTA 21
*
*     CASO DE LISTAR AYUDAP
*
30    OPCION IMPRIMIR ARCHIVO BORRAR COL. 80 ENC. 10 INI-PRO $
            40 TEXTO-AYUDA LET. 'TEXTO DE AYUDA DE PROGRAMA'
      OPCION DISCO AYUDAP INICIO-G1
31    BUSCAR DISCO AYUDAP EJECUTA 40 SEC-G1
      LEER DISCO AYUDAP INI-PRO TEXTO-AYUDA
      DETALLE 10 INI-PRO
      IMPRIMIR DETALLE 40 TEXTO-AYUDA LONG. 40
      IMPRIMIR DETALLE 1 '0' 2 80'* / 1 '0'
      EJECUTA 31
*
*     VER EL LISTADO E IMPRIMIR
*
40    OPCION TERMINAL AREA 2 /INICIO-USO-PRIMARIO
      LEER TERMINAL EJECUTA 50 NUM1
      SI NUM1 <> 1 EJECUTA 44
      OPCION TERMINAL AREA 3 /INICIO-USO-PRIMARIO
      LEER TERMINAL EJECUTA 50 PAL-BUSC
      OPCION IMPRIMIR DESPLEGAR-ARCHIVO PAL-BUSC
      EJECUTA 40
44    SI NUM1 = 2 OPCION IMPRIMIR IMPRIMIR-ARCHIVO BORRAR
      SI NUM1 = 3 OPCION IMPRIMIR BORRAR
      EJECUTA 1
*
*     TERMINAR
*
      IGUAL AREA N1 COND-E
      IGUAL AREA N1 AREA-E
50    SACAR PARAMETROS CONDICION-EJECUTA COND-E NUMERO-DE-AREA AREA-E
      SI AREA-E = 1 Y COND-E = 3 FIN 'DCF0'
      SI COND-E = 3 EJECUTA 1
      FIN
*
*     INCLUIR RUTINAS DE AYUDA
*
&I AYUP
