* PSDCBA
      PROGRAMA 'Programas que usan un archivo'
      DOCUMENTACION 1 2
*D
*D    ESTE PROGRAMA SIRVE PARA BUSCAR QUE PROGRAMAS USAN
*D    UN ARCHIVO ESPECIFICO, LA INFORMACION SE DESPLIEGA EN
*D    LA TERMINAL O SE IMPRIME.
*
*     DEFINIR AREAS PARA PREGUNTAR POR ARCHIVO
*
      OPCION TERMINAL AREA 100 /RENGLON /POS. 5 5 /LONG. 7 70 $
      /MARCO /BN NO-E VI NO-E $
      /COLOR AMARILLO AMARILLO NEGRO AZUL BLANCO $
      /TECLAS-DE-FUNCION 1 'Terminar' 2 'Men£' 3 '*Ayuda' $
      /CONDICION-EJECUTA '/F' '/M' $
      /INF-GLOBAL /TAB. 5 45 /CAMPOS 3 5 PREARC PRE-NOM-PER TOI
*
      OPCION TERMINAL AREA 101 /COLUMNA 3 /POS. 9 20 /LONG. 11 60 $
      /MARCO /COLOR CELESTE CELESTE NEGRO /BN VI NO-E $
      /CAMPOS 'DBD' INI-DBD /VAR. NOM-PER /ESC. /CONTROL-DE-GRUPO $
       NOM-PER-EXT /VAR.
*
      OPCION TERMINAL AREA 102 /RENGLON 1 1 /POS. 11 5 /LONG. 8 70 $
      /MARCO /COLOR CELESTE CELESTE NEGRO /CONFIRMAR /CAMPOS $
      2 3 'Esta opcion sirve para desplegar $
          $o imprimir los programas que' $
      3 3 'usen un archivo permanente.' $
      4 3 '-Contestar SI a la PRIMER pregunta $
          $ocacionara se despliegen los' $
      5 4 'nombres de los archivos de las DBD $
          $para seleccionar uno.' $
      6 3 '-La SEGUNDA pregunta se debe contestar $
          $con el nombre del ARCHIVO.' $
      7 3 '-Se pueden desplegar los programas por $
          $Terminal o bien Imprimir.'
*D
*D    PREGUNTAR SI SE DEPLIEGAN LOS DIFERENTES ARCHIVOS QUE HAY
*D    PARA ELLO SE RECORRE EL R0 EN FORMA SECUENCIAL Y SE
*D    DESPLIEGA EL CONTENIDO DEL R1
*
1     OPCION TERMINAL AREA 100 /DESPLEGAR
      LEER TERMINAL EJECUTA 20 PREARC
      SI PREARC = 'NO' EJECUTA 5
      OPCION TERMINAL AREA 101 /DESPLEGAR /SALVAR-ANTERIORES $
         /EMPALMAR
2     BUSCAR DISCO DOCSIS EJECUTA 4 SEC-G1
      LEER DISCO DOCSIS INI-DBD
      OPCION DISCO DOCSIS ORD-R1 A NOM-PER
      BUSCAR RECURRENTE DOCSIS 1 EJECUTA 2 ORD.
      LEER DISCO DOCSIS NOM-PER NOM-PER-EXT
      ESCRIBIR TERMINAL NOM-PER NOM-PER-EXT INI-DBD
3     BUSCAR RECURRENTE DOCSIS 1 EJECUTA 2 ORD.
      LEER DISCO DOCSIS NOM-PER NOM-PER-EXT
      ESCRIBIR TERMINAL NOM-PER NOM-PER-EXT
      EJECUTA 3
4     OPCION TERMINAL AREA 101 /TERMINAR
*D
*D    SE LEE EL NOMBRE DEL ARCHIVO Y SE BUSCA EL PRIMER
*D    PROGRAMA QUE LO USE EN EL R9. SE SACA LA FECHA DE ACTUALIZACION
*D    DEL R15  Y EL NOMBRE EXTENDIDO DEL R1
*
5     LEER TERMINAL EJECUTA 20 PRE-NOM-PER
      MOVER PRE-NOM-PER A NOM-PER-PRO
      BUSCAR DISCO DOCSIS EJECUTA 8 PRIN-G3 NOM-PER-PRO
      BUSCAR RECURRENTE DOCSIS 15 EJECUTA 6 SUP.
      LEER DISCO DOCSIS FEC-ACT HOR-ACT
      MOVER PRE-NOM-PER A NOM-PER
      BUSCAR RECURRENTE DOCSIS 1 EJECUTA 7 INF. NOM-PER
      LEER DISCO DOCSIS NOM-PER-EXT
      EJECUTA 10
6     ERROR 'ERROR 2 EN PSDCBA' 'NO TIENE FECHA DE ACTUALIZACION'
      FIN
7     ERROR 'ERROR 2 EN PSDCBA' 'NO EXISTE PERMANENTE'
      FIN
8     ERROR 'ARCHIVO INEXISTENTE O NO USADO'
      EJECUTA 5
*D
*D    PREGUNTA SI POR TERMINAL O IMPRESORA. Y DEFINE LOS LETREROS
*
10    LEER TERMINAL EJECUTA 20 TOI
      SI TOI =  'T' EJECUTA 50
      SI TOI =  'I' EJECUTA 30
      ERROR 'No tecleo T O I'
      EJECUTA 10
*D
*D    INVESTIGAR EJECUTA #
*
20    SACAR PARAMETROS CONDICION-EJECUTA COND
      SI COND = -1  EJECUTA 1000
      SI COND =  1  EJECUTA 1000
      SI COND = -4  EJECUTA 1000
      SI COND =  2  EJECUTA  999
      SI COND = -5  EJECUTA  999
      OPCION TERMINAL AREA 102 /DESPLEGAR /SALVAR-ANTERIORES /EMPALMAR
      OPCION TERMINAL AREA 102 /TERMINAR
      EJECUTA 1
*D
*D    SE BUSCA EN EL GRUPO DE LLAVES 3, POR NO PRINCIPAL, CON
*D    EL NOMBRE DEL ARCHIVO. DE LOS R8 ENCONTRADOS SE DESPLIEGA
*D    LA INFORMACION DE LOS PROGRAMAS.
*
30    OPCION IMPRIMIR COL. 120 LET. 'PROGRAMAS QUE USAN UN ARCHIVO'  $
      FECHA FEC                                                      $
      ENC. 2 GUION40 42 GUION40 82 GUION40                           $
*
      ENC.       2 ULT-ACT 40 FEC-ACT VAR.  50 HOR-ACT     VAR.      $
      ENC. 1 '0' 2 NOM-PER 10 NOM-PER VAR.  40 NOM-PER-EXT VAR.      $
      ENC. 1 '0' 2 NOM-PRO-EXT   50 'DBD/SIS/GRU'   63  DIS-PRO      $
*
      ENC. 2 GUION40 42 GUION40 82 GUION40
*
      SACAR PARAMETROS FECHA FEC
      OPCION DISCO DOCSIS INICIO-G3
31    BUSCAR DISCO DOCSIS EJECUTA 999 NO-PRIN-G3 NOM-PER-PRO
      LEER DISCO DOCSIS NOM-PRO NOM-PRO-EXT DIS-PRO
      LEER DISCO DOCSIS INI-DBD
      LEER DISCO DOCSIS NUM-SIS
      LEER DISCO DOCSIS NUM-GRU
      IMPRIMIR   DETALLE                 2   NOM-PRO                 $
      10 NOM-PRO-EXT                    50   INI-DBD                 $
      54 NUM-SIS                        58   NUM-GRU                 $
      63 DIS-PRO            
      EJECUTA 31
*D
*D    DEFINIR EL AREA PARA DESPLEGARLOS Y USAR LA MISMA
*D    LOGICA DE IMPRESION.
*
      OPCION TERMINAL AREA 103 /RENGLON /POS. 5 5 /LONG. 4 70 $
      /MARCO /COLOR CELESTE CELESTE NEGRO /BN VI $
      /TAB. 5 20 /CAMPOS NOM-PER /ESC. 3 20 NOM-PER-EXT /VAR.
      OPCION TERMINAL AREA 104 /COLUMNA 2 /POS. 10 5 /LONG. 10 70 $
      /MARCO /COLOR AMARILLO AMARILLO NEGRO /BN VI NO-E NO-E $
      /CAMPOS NOM-PRO /ESC. NOM-PRO-EXT /ESC. 'SIS/GRU' $
         NUM-SIS /VAR. NUM-GRU  /VAR.
50    OPCION TERMINAL AREA 103 104 /DESPLEGAR
      ESCRIBIR TERMINAL NOM-PER NOM-PER-EXT
      OPCION DISCO DOCSIS INICIO-G3
51    BUSCAR DISCO DOCSIS EJECUTA 52 NO-PRIN-G3 NOM-PER-PRO
      LEER DISCO DOCSIS NOM-PRO NOM-PRO-EXT
      LEER DISCO DOCSIS NUM-SIS
      LEER DISCO DOCSIS NUM-GRU
      ESCRIBIR TERMINAL NOM-PRO NOM-PRO-EXT NUM-SIS NUM-GRU
      EJECUTA 51
52    OPCION TERMINAL AREA 103 104 /TERMINAR
*
999   FIN  'DCME'
1000 FIN
