*PSDCDC
      PROGRAMA 'PROGRAMAS NO DOCUMENTADOS'
      DOCUMENTACION 1 3
*D
*D    ESTE PROGRAMA SIRVE PARA LISTAR LOS PROGRAMAS NO
*D    DOCUMENTADOS DE UNA DBD.
*D
*D    SE LEE LAS INICIALES DE DBD Y SE SACA LA FECHA DE
*D    ACTUALIZACION DEL R15.
*
      OPCION TERMINAL AREA 300 /RENGLON /POS. 5 25 /LONG. 3 30 $
       /MARCO /BN NO-E VI NO-E $
      /TECLAS-DE-FUNCION 1 'TERMINAR  ELS' 2 'MENU DOC' 3 '? AYUDA' $
      /CONDICION-EJECUTA '/F' '/M' $
       /COLOR CELESTE CELESTE NEGRO AZUL BLANCO $
       /CAMPOS  INI-DBD /INF.
*
       OPCION TERMINAL AREA 301 /RENGLON 1 1 /POS. 10 5 /LONG. 5 70 $
        /MARCO /COLOR BLANCO BLANCO NEGRO /CONFIRMAR $
        /CAMPOS $
                 2 3 'Esta opcion sirve listar los' $
                     'programas NO DOCUMENTADOS' $
                 3 3 'de una DBD para que se' $
                     'documenten.' $
                 4 3 '-Se debe especificar las iniciales' $
                     'de la DBD que se desea.'
*
1     OPCION TERMINAL AREA 300 /DESPLEGAR
2     LEER TERMINAL EJECUTA 8 INI-DBD
      BUSCAR DISCO DOCSIS EJECUTA 4 PRIN-G1 INI-DBD
      BUSCAR RECURRENTE DOCSIS 15 EJECUTA 3 SUP.
      LEER DISCO DOCSIS FEC-ACT HOR-ACT
      EJECUTA 5
3     ERROR 'ERROR 2 EN PSDCDC' 'NO EXISTE FECHA DE ACTUALIZACION'
      FIN
4     ERROR 'DBD INEXISTENTE'
      EJECUTA 2
*D
*D    SE REVISA SI HAY PROGRAMA NO DOCUMENTADOS, PARA ELLO SE BUSCA
*D    EL SISTEMA CERO EN R06
*
5     NUM-SIS = 0
      BUSCAR RECURRENTE DOCSIS 6 EJECUTA 6 SUP. NUM-SIS
      EJECUTA 30
6     ERROR 'NO HAY PROGRAMAS NO DOCUMENTADOS'
      EJECUTA 2
*D
*D    PROCESAR AYUDA
*
8     SACAR PARAMETROS CONDICION-EJECUTA COND
      SI COND = -1 EJECUTA 1000
      SI COND = 1  EJECUTA 1000
      SI COND = -4 EJECUTA 1000
      SI COND = 2  EJECUTA 999
      SI COND = -5 EJECUTA 999
      OPCION TERMINAL AREA 301 /DESPLEGAR /SALVAR-ANTERIORES /EMPALMAR
      OPCION TERMINAL AREA 301 /TERMINAR
      EJECUTA 2
*D
*D    SE INICIALIZAN LETREROS
*
30    OPCION IMPRIMIR COL. 80 LET. 'NO DOCUMENTADOS' $
       FECHA FEC $
       ENC. 2 GUION40 42 GUION40 $
       ENC. 2 ULT-ACT 40 FEC-ACT VAR. 50 HOR-ACT VAR. $
       ENC. 1 '0' 2 'DBDS' 6 INI-DBD VAR. $
       ENC. 1 '0' 2 NOM-PRO-EXT  $
       ENC. 2 GUION40 42 GUION40
      SACAR PARAMETROS FECHA FEC
*D
*D    SE BUSCA EL GRUPO CERO Y LUEGO SE RECORRE EL R8 PARA
*D    IMPRIMIR EL NOMBRE DE LOS PROGRAMAS NO DOCUMENTADOS
*
      NUM-GRU = 0
      BUSCAR RECURRENTE DOCSIS 7 EJECUTA 35 INF. NUM-GRU
      OPCION DISCO DOCSIS ORD-R8 A NOM-PRO
31    BUSCAR RECURRENTE DOCSIS 8 EJECUTA 1 ORD.
      LEER DISCO DOCSIS NOM-PRO NOM-PRO-EXT
      IMPRIMIR DETALLE   2 NOM-PRO 10 NOM-PRO-EXT
      EJECUTA 31
35    ERROR 'ERROR 2 EN PSDCDC' 'NO TIENE GRUPO CERO'
      FIN
999   FIN 'DCME'
1000  FIN
