* PSDCF4
       PROGRAMA 'PASO ENTRE MAQUINAS'  DIR /COLOR AZUL AMARILLO
       DOCUMENTACION 3 0
       SI DIR-PER-TEM = ' ' EJECUTA 1
       OPCION DISCO AYUDAA DISCO DIR-PER-TEM
       OPCION DISCO AYUDAV DISCO DIR-PER-TEM
       OPCION DISCO AYUDAP DISCO DIR-PER-TEM
*
*D    ESTE PROGRAMA SIRVE PARA GENERAR EL T801 CON LA INFORMACION DE
*D    LOS ARCHIVOS AYUDAA, AYUDAV Y AYUDAP. CON EL T801 EN LA OTRA
*D    MAQUINA SE GENEREN NUEVAMENTE ESTOS ARCHIVOS.
*
*     DEFINIR AREA DE MENU
*
      IGUAL AREA N1 NUM
      OPCION  TERMINAL  AREA  1  /MENU  /MARCO                  $
      /POS.  5  5    /LONG.  3  70                              $
      /COLOR  BLANCO BLANCO NEGRO  NEGRO AMARILLO  CELESTE NEGRO  $
      /TECLAS-DE-FUNCION  1 'TERMINAR'   2 '*AYUDA'   3 'MENU' $
        /AYUDA-GLOBAL DESPLEGAR-AYUDA                           $
      /BN  NO-E  VI  NO-E                                       $
      /CAMPOS                                                   $
      1 '*AYUDAS--->T801' 2 '*T801--->AYUDAS/E' 3 'T801--->AYUDAS/B' $
       NUM /VAR-SEL.
*
*     DEFINIR AREA DE CONTADOR
*
      IGUAL AREA N1 NUM-TEXTO-AYUDA
      OPCION TERMINAL AREA 2 /RENGLON /MARCO /POS. 10 5 /LONG. 3 70 $
      /COLOR  BLANCO BLANCO NEGRO  NEGRO AMARILLO  CELESTE NEGRO  $
      /BN  NO-E  VI  NO-E                                       $
       /CAMPOS 'TEXTOS DE AYUDA EN T801' NUM-TEXTO-AYUDA /VAR.
*
*     DESPLEGAR AREAS Y LEER SELECCION
*
1     OPCION TERMINAL AREA 1 2 /DESPLEGAR
      LEER TERMINAL EJECUTA 50 NUM
      SI NUM <> 1 EJECUTA 30
*
*     CASO DE GENERAR T801, RECORRER ARCHIVOS
*
      OPCION TEMPORAL 801 /ASCII /ESCRITURA /DISCO DIR-PER-TEM
      OPCION DISCO AYUDAV INICIO-G1
      NUM-TEXTO-AYUDA = 0
      NUM-AREA = 0
      MOVER 'Sistema de ayudas de SISINF ********************' $
            A RELLENO-T801-X38
10    BUSCAR DISCO AYUDAV EJECUTA 11 SEC-G1
      LEER DISCO AYUDAV NOM-VAR INI-PRO TEXTO-AYUDA
      ESCRIBIR TEMPORAL 801 1 NOM-VAR INI-PRO NUM-AREA $
                                       RELLENO-T801-X38
      ESCRIBIR TEMPORAL 801 TEXTO-AYUDA
      NUM-TEXTO-AYUDA = NUM-TEXTO-AYUDA + 1
      EJECUTA 10
11    OPCION DISCO AYUDAA INICIO-G1
      MOVER ' ' A NOM-VAR
12    BUSCAR DISCO AYUDAA EJECUTA 13 SEC-G1
      LEER DISCO AYUDAA NUM-AREA INI-PRO TEXTO-AYUDA
      ESCRIBIR TEMPORAL 801 2 NOM-VAR INI-PRO NUM-AREA $
                                       RELLENO-T801-X38
      ESCRIBIR TEMPORAL 801 TEXTO-AYUDA
      NUM-TEXTO-AYUDA = NUM-TEXTO-AYUDA + 1
      EJECUTA 12
13    OPCION DISCO AYUDAP INICIO-G1
      NUM-AREA = 0
14    BUSCAR DISCO AYUDAP EJECUTA 15 SEC-G1
      LEER DISCO AYUDAP INI-PRO TEXTO-AYUDA
      ESCRIBIR TEMPORAL 801 3 NOM-VAR INI-PRO NUM-AREA $
                                       RELLENO-T801-X38
      ESCRIBIR TEMPORAL 801 TEXTO-AYUDA
      NUM-TEXTO-AYUDA = NUM-TEXTO-AYUDA + 1
      EJECUTA 14
15    ESCRIBIR TERMINAL NUM-TEXTO-AYUDA
      OPCION TERMINAL AREA 1 2 /TERMINAR
      FIN 'DCF0'
*
*     AGREGAR A AYDUDAV, AYUDAA Y AYUDAP
*
30    OPCION TEMPORAL 801 /LECTURA /ASCII /DISCO DIR-PER-TEM
      IGUAL AREA N1 TIPO-ARCHIVO
      NUM-TEXTO-AYUDA = 0
31    LEER TEMPORAL 801 EJECUTA 40 TIPO-ARCHIVO $
               NOM-VAR INI-PRO NUM-AREA RELLENO-T801-X38
      LEER TEMPORAL 801 EJECUTA 40 TEXTO-AYUDA
      SI TIPO-ARCHIVO <> 1 EJECUTA 33
      BUSCAR DISCO AYUDAV EJECUTA 32 PRIN-G1 NOM-VAR INI-PRO
      ERROR 'YA EXISTE EN AYUDAV' NOM-VAR INI-PRO
      SI NUM = 2 EJECUTA 31
      BORRAR DISCO AYUDAV
32    INSERTAR DISCO AYUDAV NOM-VAR INI-PRO TEXTO-AYUDA
      NUM-TEXTO-AYUDA = NUM-TEXTO-AYUDA + 1
      EJECUTA 31
33    SI TIPO-ARCHIVO <> 2 EJECUTA 35
      BUSCAR DISCO AYUDAA EJECUTA 34 PRIN-G1 NUM-AREA INI-PRO
      ERROR 'YA EXISTE EN AYUDAA' NUM-AREA INI-PRO
      SI NUM = 2 EJECUTA 31
      BORRAR DISCO AYUDAA
34    INSERTAR DISCO AYUDAA NUM-AREA INI-PRO TEXTO-AYUDA
      NUM-TEXTO-AYUDA = NUM-TEXTO-AYUDA + 1
      EJECUTA 31
35    SI TIPO-ARCHIVO <> 3 EJECUTA 37
      BUSCAR DISCO AYUDAP EJECUTA 36 PRIN-G1 INI-PRO
      ERROR 'YA EXISTE EN AYUDAP' INI-PRO
      SI NUM = 2 EJECUTA 31
      BORRAR DISCO AYUDAP
36    INSERTAR DISCO AYUDAP INI-PRO TEXTO-AYUDA
      NUM-TEXTO-AYUDA = NUM-TEXTO-AYUDA + 1
      EJECUTA 31
37    ERROR 'TIPO INVALIDO' TIPO-ARCHIVO
      FIN
40    ESCRIBIR TERMINAL NUM-TEXTO-AYUDA
      OPCION TERMINAL AREA 1 2 /TERMINAR
      FIN 'DCF0'
*
*     TERMINAR
*
      IGUAL  AREA      N1   COND-E
*
50    SACAR  PARAMETROS CONDICION-EJECUTA COND-E
      SI COND-E = 3 FIN 'DCF0'
      FIN
*
*     INCLUIR RUTINAS DE AYUDA
*
&I AYUP
OPCION TERMINAL AREA 999 /ERROR /TIEMPO 0 0
