*PSDCDD
      PROGRAMA 'VARIABLES PARA CAS DE UNA DBD'
      DOCUMENTACION 1 3
*D
*D    ESTE PROGRAMA SIRVE PARA LISTAR LAS VARIABLES DE LOS DIFERENTES
*D    GRUPOS DE CAS DE LOS ARCHIVOS DE UNA DBD.
*D
*D    SE LEE LAS INICIALES DE DBD Y SE SACA LA FECHA DE
*D    ACTUALIZACION DEL R15.
*
      OPCION TERMINAL AREA 300 /RENGLON /POS. 5 25 /LONG. 3 30 $
       /MARCO /BN NO-E VI NO-E $
      /TECLAS-DE-FUNCION 1 'TERMINAR  ELS' 2 'MENU DOC' 3 '? AYUDA' $
      /CONDICION-EJECUTA '/F' '/M' $
       /COLOR CELESTE CELESTE NEGRO AZUL BLANCO $
       /CAMPOS  INI-DBD /INF.
*
       OPCION TERMINAL AREA 301 /RENGLON 1 1 /POS. 10 5 /LONG. 5 70 $
        /MARCO /COLOR BLANCO BLANCO NEGRO /CONFIRMAR $
        /CAMPOS $
                 2 3 'Esta opcion sirve listar las' $
                     'Variables de CAS para el usuario' $
                 3 3 'final. El listado es por Archivo' $
                     'de una DBD, Grupo y Variable.' $
                 4 3 '-Se debe especificar las iniciales' $
                     'de la DBD que se desea.'
*
1     OPCION TERMINAL AREA 300 /DESPLEGAR
2     LEER TERMINAL EJECUTA 5 INI-DBD
      BUSCAR DISCO DOCSIS EJECUTA 4 PRIN-G1 INI-DBD
      BUSCAR RECURRENTE DOCSIS 15 EJECUTA 3 SUP.
      LEER DISCO DOCSIS FEC-ACT HOR-ACT
      EJECUTA 30
3     ERROR 'ERROR 2 EN PSDCDC' 'NO EXISTE FECHA DE ACTUALIZACION'
      FIN
4     ERROR 'DBD INEXISTENTE'
      EJECUTA 2
*D
*D    PROCESAR AYUDA
*
5     SACAR PARAMETROS CONDICION-EJECUTA COND
      SI COND = -1 EJECUTA 1000
      SI COND = 1  EJECUTA 1000
      SI COND = -4 EJECUTA 1000
      SI COND = 2  EJECUTA 999
      SI COND = -5 EJECUTA 999
      OPCION TERMINAL AREA 301 /DESPLEGAR /SALVAR-ANTERIORES /EMPALMAR
      OPCION TERMINAL AREA 301 /TERMINAR
      EJECUTA 2
*D
*D    SE INICIALIZAN LETREROS
*
30    OPCION IMPRIMIR COL. 80 LET. 'GRUPOS Y VARIABLES PARA EL CAS' $
       FECHA FEC $
       ENC. 2 GUION40 42 GUION40 $
       ENC. 2  'ULTIMA ACTUALIZACION DE ESTA DBD'              $
            40 FEC-ACT VAR. 50 HOR-ACT VAR. $
       ENC. 1 '0' 2 'DBDS' 6 INI-DBD VAR. $
       ENC. 1 '0' 2 NOM-PER 10 NOM-PER VAR.  40 NOM-PER-EXT VAR. $
       ENC. 1 '0' 2 NUM-GRU-CAS 10 NOM-GRU-CAS 40 NOM-VAR-CRT $
       ENC. 2 GUION40 42 GUION40
      SACAR PARAMETROS FECHA FEC
*D
*D    SE LEE EL R1 CON LA INFORMACION DE LOS ARCHIVOS ORDENADOS,
*D    COMO LOS NUMEROS DE GRUPO SON DE 1 A UN MAXIMO SE
*D    LOCALIZA LEYENDO EL R2 Y R3. CUANDO NO HAY MAS SE TERMINA.
*D    SE LEE EL R4 CON LA INFORMACION DE LAS VARIABLES.
*
      OPCION DISCO DOCSIS ORD-R1 A NOM-PER
31    BUSCAR RECURRENTE DOCSIS 1 EJECUTA 999 ORD.
      LEER DISCO DOCSIS NOM-PER NOM-PER-EXT
      BRINCAR
*
      NUM-GRU-CAS = 0
32    NUM-GRU-CAS = NUM-GRU-CAS + 1
      OPCION DISCO DOCSIS INICIO-R2
33    BUSCAR RECURRENTE DOCSIS 2 EJECUTA 31 SIG.
      BUSCAR RECURRENTE DOCSIS 3 EJECUTA 33 SUP. NUM-GRU-CAS
      LEER DISCO DOCSIS NUM-GRU-CAS NOM-GRU-CAS
      IGUAL AREA X20 LET-CONT
      MOVER ' ' A LET-CONT
      IMPRIMIR ENCABEZADO  2 NUM-GRU-CAS VAR. 10 NOM-GRU-CAS $
        VAR. 60 LET-CONT VAR.
      MOVER '(CONTINUACION)' A LET-CONT
*
34    BUSCAR RECURRENTE DOCSIS 4 EJECUTA 32 ANT.
      LEER DISCO DOCSIS NOM-VAR-CRT
      IMPRIMIR DETALLE 40 NOM-VAR-CRT
      EJECUTA 34
999   FIN 'DCME'
1000  FIN
