* PSDCEC
*D
*D    ESTE PROGRAMA SIRVE PARA DAR CIERTOS MANTENIMIENTOS A
*D    EL ARCHIVO DOCSIS COMO SON:
*D
*D    -BORRAR PROGRAMAS
*D    -BORRAR GRUPOS
*D    -BORRAR SISTEMAS
*D
*D    LO ANTERIOR ES NECESARIO YA QUE UN PROGRAMA ESTA EN PSXXYY,
*D    EN ESXXYY, EN DOCSXX Y EN DOCSIS. CON ESTA OPCION SE BORRA
*D    DE  DOCSXX Y DE DOCSIS Y SE BORRA EL ESXXYY.
*D
*D    NOTE QUE NO SE BORRA EL PSXXYY EL CUAL SE DEBE BORRAR.
*D    ANTES o DESPUES, ESTA OPCION SE USA TAMBIEN AL RENOMBRAR.
*
*     CUANDO UN GRUPO O UN SISTEMA SE QUITA DE LA DBD, EL PROGRAMA
*D    QUE ACTUALIZA DOCSIS (PSDCEB) NO LO BORRA, POR LO QUE ES
*D    NECESARIO USAR ESTA OPCION. CUANDO UN PROGRAMA NO TIENE
*D    SISTEMA O GRUPO SE PONE EN EL SISTEMA NO DOCUMENTADO, UNA
*D    VEZ QUE SE CORRIGE ESTE PROGRAMA ESTE SISTEMA (NO DOCUMENTADO)
*D    SE BORRA CON ESTA OPCION.
*
*     DEFINIR AREAS PARA LEER INICIALES DE DBD Y OPCION
*--------------------------------------------------------------------
      PROGRAMA 'MANTENIMIENTO A DOCSIS'
      DOCUMENTACION 1 5
      OPCION  TERMINAL  AREA   290   /RENGLON                  $
      /POS.  2  5   /LONG.  11 70    /MARCO                    $
      /COLOR  CELESTE  CELESTE NEGRO AZUL BLANCO               $
      /BN   NO-E  VI  NO-E                                     $
      /CAMPOS                                                  $
      'Los programas dentro del sistema de documentacion'      $
      'se encuentran en tres lugares:'   /INICIO-DE-RENGLON    $
      ' '                                /INICIO-DE-RENGLON    $
      '1) En archivo DOCSXX   (Indice de programas)'           $    
                                         /INICIO-DE-RENGLON    $
      '2) En archivo DOCSIS   (Documentacion general)'         $
                                         /INICIO-DE-RENGLON    $   
      '3) En archivo ESXXYY   (Programa objeto)'               $
      ' '                                  /INICIO-DE-RENGLON  $
      'Este programa borra de los tres lugares'                $
                                            /INICIO-DE-RENGLON $
      'DESEA CONTINUAR  ?'                 /INICIO-DE-RENGLON  $
      10  41  PRECONT    /LEC.    /VAR.    /INF.
*
*  area  para  pedir  iniciales de  DBD
*
      OPCION TERMINAL AREA 300 /RENGLON /POS. 2 1 /LONG. 3 25 $
      /MARCO /BN NO-E VI NO-E $
      /TECLAS-DE-FUNCION 1 'TERMINAR  ELS' 2 'MENU DOC'             $
      /CONDICION-EJECUTA '/F' '/M' $
       /COLOR CELESTE CELESTE NEGRO AZUL BLANCO $
       /CAMPOS  INI-DBD /EDITAR
*
* seleccion de  ( programa, grupo o sistema )
*
       IGUAL AREA N10 OP-B
      OPCION TERMINAL AREA 301 /MENU /POS. 2 40 /LONG. 3  40         $
       /MARCO /BN NO-E VI NO-E                                       $
      /TECLAS-DE-FUNCION 1 'TERMINAR  ELS' 2 'MENU DOC'              $
       /COLOR CELESTE CELESTE NEGRO ROJO BLANCO CELESTE NEGRO        $
       /CAMPOS                                                       $
        1  'PROGRAMAS'    2 'GRUPOS'     3 'SISTEMAS'                $
               OP-B /VAR-SEL.
*
*  AREA  PARA  CAPTURAR LOS PROGRAMAS A BORRAR DEL SISTEMA.
*
      OPCION  TERMINAL  AREA   310  /RENGLON  0 0              $
      /POS.  5  1   /LONG.   9   80 /MARCO  /BN NO-E VI        $
      /COLOR  CELESTE  CELESTE  NEGRO  BLANCO  AZUL            $
*
      /CAMPOS                                                  $
      'SI SE TECLEA :'                                         $
      '\ .-                       en cualquier'   /INICIO-DE-RENGLON $
      ' campo se saldra a sistema operativo.'                        $
      ' '                                         /INICIO-DE-RENGLON $
      '"F5" (no borrar) o /NO-BORRAR .- en el '   /INICIO-DE-RENGLON $
      'DIRECTORIO no se borrara ese programa'                        $
      ' '                                         /INICIO-DE-RENGLON $
      '"F6" (borrar) o /B            .- en el '   /INICIO-DE-RENGLON $
      'nombre del programa como ultimo campo'                        $
       8 36 'se le indica que principia a borrar.'
*
* pedir los programas a dar de baja
*
      OPCION TERMINAL AREA 312  /COLUMNA  2  2                  $
      /POS. 14  1    /LONG.  8  80   /MARCO   /BN  NO-E  VI     $
      /TECLAS-DE-FUNCION 1 'TERMINAR  ELS' 2 'MENU DOC'         $
                         5 'NO BORRA'      6 'BORRAR'           $
      /CONDICION-EJECUTA '/F' '/M' '/NO-BORRAR' '/B'            $
      /COLOR  CELESTE  CELESTE NEGRO  BLANCO AZUL               $
*
      /CAMPOS                                                   $
       NOM-PRO /INF.    DIS-PRO     /BLANCOS
*
*  enviar mensage de ayuda para seleccion de borrar GRUPOS o SISTEMAS
*
      IGUAL  AREA   X8  GPO-SIS
      IGUAL  AREA   X8  GPO-SIS-M1
      IGUAL  AREA   X8  GPO-SIS-M2
      OPCION  TERMINAL  AREA   306   /RENGLON                  $
      /POS.  5  5   /LONG.  8  70    /MARCO                    $
      /COLOR CELESTE  CELESTE NEGRO AZUL BLANCO CELESTE  NEGRO $
      /BN   NO-E  VI  NO-E                                     $
      /CAMPOS                                                  $
      'BORRAR'  GPO-SIS   /VAR.                                $
      'ANTES.- de ejecutar esta opcion se'  /INICIO-DE-RENGLON $
      'deberan de dar de baja'                                 $
      'todos los programas de los'  GPO-SIS-M1  /VAR.          $
      'que se desean borrar.'                                  $
      'EN ESTA OPCION .- se borran los'     /INICIO-DE-RENGLON $
       GPO-SIS-M2 /VAR. 'con cero programas'                   $
       'del archivo DOCSIS'                                    $
      'DESEA CONTINUAR  ?           ' /INICIO-DE-RENGLON       $
      PRECONT  /VAR.  /LEC.  /INF.
*
*  enviar aviso despues de borrar los GRUPOS o SISTEMAS
*
      OPCION  TERMINAL  AREA   308   /RENGLON                  $
      /POS.  17 5   /LONG.   5 70    /MARCO   /CONFIRMAR       $
      /COLOR  VERDE    VERDE  NEGRO                            $
      /BN   NO-E  VI  NO-E                                     $
      /CAMPOS                                                  $
      'se debera de editar la DBDSXX'                         $
      'y borrar los'    GPO-SIS-M1  /VAR.   'que fueron'      $
      'borrados en este proceso'                              $
      'y compilarla, de lo contrario habra'                   $
      'inconsistencias' 'entre los archivos' 'DOCSXX y DOCSIS'
*
      IGUAL DOCSIS INI-DBD INI-DBD-A
      IGUAL DOCSIS INI-DBD INI-DBD-B
*
      IGUAL AREA X10 BORRADO
      OPCION TERMINAL AREA 316  /MARCO  /BN  VI  NO-E              $
      /COLOR  CELESTE  CELESTE NEGRO   /POS. 14 5     /LONG.  8 70 $
      /COLUMNA 2 0 5 /CAMPOS 'SIS/GRU' NUM-SIS /VAR. NUM-GRU /VAR. $
       NOM-GRU /ESC. 'PROGRAMAS' TOT-NUM-PRO /VAR.  BORRADO /VAR.
*
      IGUAL AREA N10 TOT-PRO-SIS
      OPCION TERMINAL AREA 324 /MARCO /BN VI NO-E $
      /COLOR CELESTE CELESTE NEGRO /POS. 14 5  /LONG. 8  70 $
      /COLUMNA 2 0 5  /CAMPOS 'SISTEMA' NUM-SIS /VAR.  $
       NOM-SIS /VAR. 'PROGRAMAS' TOT-PRO-SIS /VAR.  BORRADO /VAR.
*---------------
*D
*D    LEER LAS INICIALES DE LA DBD A QUE SE DA MANTENIMIENTO
*---------------
      OPCION  TERMINAL  AREA  290   /DESPLEGAR
      LEER  TERMINAL  EJECUTA  1000  PRECONT
      SI PRECONT  =  'NO'  EJECUTA  999
      OPCION  TERMINAL  AREA  290   /TERMINAR
*
1     OPCION TERMINAL AREA 300 301 /DESPLEGAR
      IGUAL AREA N10 NUM-AREA-PRG
      NUM-AREA-PRG = 300
2     LEER TERMINAL EJECUTA 7 INI-DBD
      BUSCAR DISCO DOCSIS EJECUTA 3 PRIN-G1 INI-DBD
      EJECUTA 5
3     ERROR 'DBD INEXISTENTE'
      EJECUTA 2
*---------------
*D
*D    LEER LA OPCION ( PROG., GRUPOS o SISTEMAS )  Y PROCESAR AYUDA
*---------------
5     NUM-AREA-PRG = 301
      LEER TERMINAL EJECUTA 7 OP-B
      SI  OP-B  =  1  EJECUTA  10    : OP-B = 1 ,  BORRAR  PROGRAMAS ;
*
      SI  OP-B  =  2  EJECUTA  49    : BORRAR  GRUPOS  ;
      EJECUTA  69                    : BORRAR  SISTEMAS  ;
*
7     SACAR PARAMETROS CONDICION-EJECUTA COND
      SI COND = -1 EJECUTA 1000    : TECLEO  \ ,  TERMINAR ;
      SI COND =  1 EJECUTA 1000    : TECLEO "F1", TERMINAR ;
      SI COND = -4 EJECUTA 1000    : TECLEO /F,   TERMINAR ;
*
      SI COND =  2 EJECUTA 999     : TECLEO "F2", MENU DOC.;
      SI COND = -5 EJECUTA 999     : TECLEO /M,   MENU DOC.;
      SI NUM-AREA-PRG = 301 EJECUTA 5
      EJECUTA 2
* ---------------
*D
*D    LEER LOS PROGRAMAS A BORRAR Y FORMAR EL T911 CON LA
*D    SIGUIENTE INFORMACION:
*D
*D    UN REGISTRO CON INFORMACION DE LA DBD
*D
*D       X2        INICIALES DE DBD
*D       X14       DISPOSITIVO DE LA DBD
*D
*D    N REGISTROS CON INF DE LOS PROGRAMAS
*D
*D       X6        NOMBRE DEL PROGRAMA COMO PSXXYY
*D       X14       DISPOSITIVO DEL PROGRAMA
*---------------
      IGUAL  DOCSIS   DIS-PRO   DIS-PRO-A
*
 10   OPCION  TERMINAL  AREA   310   312                     $
      /SALVAR-ANTERIORES   /DESPLEGAR   /EMPALMAR
      OPCION TEMPORAL 911 ESCRITURA ASCII
      LEER DISCO DOCSIS DIS-DBD
      ESCRIBIR TEMPORAL 911 INI-DBD DIS-DBD
*
* REVISA QUE LAS POSICIONES 1 Y 2  SEAN  "PS"
 11   LEER TERMINAL EJECUTA  18  NOM-PRO
      CONVERTIR NOM-PRO A X2 POS. 1 1 EJECUTA 90
      CONVERTIR NOM-PRO A X2 POS. 2 2 EJECUTA 90
      SI X2 = 'PS' EJECUTA  12
      ERROR 'NOMBRE DE PROGRAMA NO EMPIEZA CON PS'
      EJECUTA 11
*
*  REVISA QUE LAS POSICIONES 3 Y 4 SEAN  LAS MISMAS DE LA DBD
 12   CONVERTIR NOM-PRO A X2 POS. 3 1 EJECUTA 90
      CONVERTIR NOM-PRO A X2 POS. 4 2 EJECUTA 90
      SI INI-DBD = X2 EJECUTA  13
      ERROR 'PORGRAMA NO PERTENECE A' INI-DBD
      EJECUTA 11
*
 13   LEER  TERMINAL  EJECUTA  18  DIS-PRO
*
 14   BUSCAR  DISCO  DOCSIS  EJECUTA  17  PRIN-G2  NOM-PRO
      LEER    DISCO  DOCSIS  DIS-PRO-A
      SI  DIS-PRO  <>   ' '      EJECUTA  16
      MOVER  DIS-PRO-A   A  DIS-PRO
 15   ESCRIBIR TEMPORAL 911 NOM-PRO DIS-PRO
      EJECUTA  11
*
 16   SI  DIS-PRO  =  DIS-PRO-A  EJECUTA  15
      ERROR 'EN PROGRAMA :' NOM-PRO 'DISPOSITIVO INCORRECTO'
      EJECUTA  13
*
 17   SI  DIS-PRO  >  '  '  EJECUTA  15
      ERROR 'PROGRAMA NO EXISTE EN DOCSIS'                    $'
            'EL DISPOSITIVO ES OBLIGATORIO'
      EJECUTA  13
*
*D
*D    PROCESAR AYUDA
*
      IGUAL AREA N10 NUM-P-D
 18   SACAR PARAMETROS  CONDICION-EJECUTA   COND  $
                        NUMERO-DE-LECTURAS  NUM-P-D
      SI COND  =  -1 EJECUTA 1000    :TECLEO \  TERMINAR ;
      SI COND  =   1 EJECUTA 1000    : "F1" ,   TERMINAR ;
      SI COND  =  -4 EJECUTA 1000    : "/F" ,   TERMINAR  ;
*
      SI COND  =   2 EJECUTA 999     : "F2" ,   MENU DE DOC.;
      SI COND  =  -5 EJECUTA 999     : "/M" ,   MENU DE DOC.;
*
      SI NUM-P-D = 2 EJECUTA  19
      SI COND  =   6 EJECUTA  25     : "F6",    BORRAR  PROGRAMAS;
      SI COND  =  -7 EJECUTA  25     : "/B",    BORRAR  PROGRAMAS ;
*
      SI COND  =   5 EJECUTA  22     : "F5",    NO BORRAR PROG.;
      SI COND  =  -6 EJECUTA  22     : "/NO-BORRAR , PROGRAMAS;
      EJECUTA  11
*
 19   SI COND  =   5 EJECUTA 11      : "F5" NO BORRAR;
      SI COND  =  -6 EJECUTA 11      : /NO-BORRAR, PROGRAMAS;
*
      SI COND  =   6 EJECUTA  22     : "F6", BORRAR PROGRAMAS;
      SI COND  =  -7 EJECUTA  22     : /B, BORRAR PROGRAMAS ;
      EJECUTA 11
*
 22   ERROR 'ESTE CAMPO NO ACEPTA ESTA:' $
            'TECLA DE FUNCION O CARACTERES ESP.'
      EJECUTA 11
*D
*D    LLAMAR AL PROGRAMA DOCBO PARA BORRAR LOS PROGRAMAS DE
*D    DOCSXX Y LOS ESXXYY. NOTE QUE EL PSXXYY LO TIENE QUE
*D    BORRAR EL USUARIO O RENOMBRARLO A OTRO NOMBRE
*
 25  OPCION TERMINAL AREA   310  312  /TERMINAR
      LLAMAR 'DOCBO ' 911
*D
*D    LEER EL TEMPORAL 911 Y GENERAR EL REPORTE DE BORRADOS,
*D    BORRAR EL PROGRAMA EN DOCSIS ACTUALIZANDO EL NUMERO
*D    DE PROGRAMAS EN UN GRUPO.
*D
*D    EL FORMATO DE T912 ES:
*D
*D    N REG CON LA INFORMACION DE PROGRAMAS
*D
*D       X6        NOMBRE DEL PROGRAMA
*D       X14       DISPOSITIVO DEL PROGRAMA
*D       N10       0=SE BORRO EN DOCSXX 1=NO ESXITE EN DOCSXX
*D       N10       0=SE BORRO EL ESXXYY O CODIGO DEL ERROR
*
      OPCION IMPRIMIR LET. 'PROGRAMAS BORRADOS' FECHA FEC $
        ENC. 5 NOM-PRO 15 DIS-PRO
      SACAR PARAMETROS FECHA FEC
      OPCION TEMPORAL 912 LECTURA ASCII
      IGUAL AREA N10 CED
      IGUAL AREA N10 CEE
30    LEER TEMPORAL 912 EJECUTA 45 NOM-PRO DIS-PRO CED CEE
*D
*D    REVISA SI SE BORRO DE DOCSIS
*
      SI CED = 1 EJECUTA 31
      DETALLE 30 'SE BORRO EN DOCS'
      DETALLE 46 INI-DBD
      EJECUTA 32
31    DETALLE 30 'NO EXISTE EN DOCS'
      DETALLE 47 INI-DBD
*D
*D    REVISA SI SE BORRO EL ESXXYY
*
32    MOVER 'ESXXYY' A  X6
      CONVERTIR NOM-PRO A X6 POS. 3 3 EJECUTA 92
      CONVERTIR NOM-PRO A X6 POS. 4 4 EJECUTA 92
      CONVERTIR NOM-PRO A X6 POS. 5 5 EJECUTA 92
      CONVERTIR NOM-PRO A X6 POS. 6 6 EJECUTA 92
      SI CEE <> 0 EJECUTA 33
      DETALLE 60 'SE BORRO EL' 0 X6
      EJECUTA 35
33    DETALLE 60 'ERROR' 0 CEE LONG. 4 0 'AL BORRAR' 0 X6
*D
*D    BORRARLO DE DOCSIS, PARA ELLO SE BUSCA POR PRINCIPAL
*D    EN EL GRUPO DE LLAVES 2
*
35    BUSCAR DISCO DOCSIS EJECUTA 36 PRIN-G2 NOM-PRO
      BORRAR RECURRENTE DOCSIS 8
      LEER DISCO DOCSIS TOT-NUM-PRO
      TOT-NUM-PRO = TOT-NUM-PRO - 1
      ESCRIBIR DISCO DOCSIS TOT-NUM-PRO
      DETALLE 90 'SE BORRO DE DOCSIS'
      EJECUTA 40
*
 36   DETALLE 90 'NO EXISTE EN DOCSIS'
 40   IMPRIMIR  DETALLE  5  NOM-PRO  15  DIS-PRO
      EJECUTA 30
*
*     POSICIONAR EL LA DBD
*
45    BUSCAR DISCO DOCSIS EJECUTA 93 PRIN-G1 INI-DBD
      OPCION TEMPORAL 912 BORRAR
      EJECUTA 1
*---------------
*D    BORRAR  GRUPOS  :
*D    PARA BORRAR LOS GRUPOS SERA NECESARIO :
*D
*D    - BORRAR TODOS LOS PROGRAMAS QUE PERTENESCAN AL GRUPO QUE
*D      SE DESEA BORRAR.
*D
*D    - EJECUTAR OPCION DE BORRAR GRUPOS, ESTA OPCION BORRA TODOS
*D      LOS GRUPOS QUE TENGAN CERO PROGRAMAS.
*
* --------------
      IGUAL  DOCSIS   NUM-SIS   IND-BOR
 49   MOVER  'GRUPOS'   A   GPO-SIS
      MOVER  'grupos'   A   GPO-SIS-M1
      MOVER  'grupos'   A   GPO-SIS-M2
      OPCION  TERMINAL  AREA  306                              $
      /SALVAR-ANTERIORES   /DESPLEGAR   /EMPALMAR
      ESCRIBIR  TERMINAL  GPO-SIS  GPO-SIS-M1  GPO-SIS-M2
      LEER  TERMINAL  EJECUTA  1000  PRECONT
      SI  PRECONT  =  'NO'  EJECUTA 999
      IND-BOR  =  0
*
 50   OPCION  TERMINAL   AREA         316                     $
      /SALVAR-ANTERIORES    /DESPLEGAR   /EMPALMAR
      OPCION DISCO DOCSIS ORD-R6 A NUM-SIS
51    BUSCAR RECURRENTE DOCSIS 6 EJECUTA 53 ORD.
      LEER DISCO DOCSIS NUM-SIS
      OPCION DISCO DOCSIS ORD-R7 A NUM-GRU
*
52    BUSCAR RECURRENTE DOCSIS 7 EJECUTA 51 ORD.
      LEER DISCO DOCSIS NUM-GRU NOM-GRU TOT-NUM-PRO
      SI NUM-GRU = 0 EJECUTA 52
      ESCRIBIR TERMINAL NUM-SIS NUM-GRU NOM-GRU TOT-NUM-PRO
      SI TOT-NUM-PRO <> 0 EJECUTA 52
      MOVER 'SE BORRO' A BORRADO
      ESCRIBIR TERMINAL BORRADO
      BORRAR RECURRENTE DOCSIS 7
      LEER DISCO DOCSIS TOT-NUM-GRU
      TOT-NUM-GRU = TOT-NUM-GRU - 1
      ESCRIBIR DISCO DOCSIS TOT-NUM-GRU
      IND-BOR  =  1
      EJECUTA 52
*
 53   SI  IND-BOR  =  0  EJECUTA  54
      OPCION  TERMINAL   AREA   308                     $
      /PROCESADA  /SALVAR-ANTERIORES   /DESPLEGAR   /EMPALMAR
      ESCRIBIR  TERMINAL   GPO-SIS-M1
      OPCION  TERMINAL  AREA    308      /TERMINAR
*
  54  OPCION  TERMINAL  AREA   316  /TERMINAR
      OPCION  TERMINAL  AREA   306  /TERMINAR
      EJECUTA  1
* --------------
*D
*D    DESPLEGAR LOS SISTEMAS DE ESTA DBD, LOS QUE TENGAN CERO
*D    PROGRAMAS SE BORRA EL SISTEMA.
*
* --------------
 69   MOVER  'SISTEMAS' A   GPO-SIS
      MOVER  'sistemas' A   GPO-SIS-M1
      MOVER  'sistemas' A   GPO-SIS-M2
      OPCION  TERMINAL  AREA  306                              $
      /SALVAR-ANTERIORES   /DESPLEGAR   /EMPALMAR
      ESCRIBIR  TERMINAL  GPO-SIS  GPO-SIS-M1  GPO-SIS-M2
      LEER  TERMINAL  EJECUTA  1000  PRECONT
      SI  PRECONT  =  'NO'  EJECUTA 999
      IND-BOR  =  0
*
70    OPCION TERMINAL AREA 324 /EMPALMAR /DESPLEGAR /SALVAR-ANTERIORES
      OPCION DISCO DOCSIS ORD-R6 A NUM-SIS
71    BUSCAR RECURRENTE DOCSIS 6 EJECUTA 74 ORD.
      LEER DISCO DOCSIS NUM-SIS NOM-SIS
      TOT-PRO-SIS = 0
72    BUSCAR RECURRENTE DOCSIS 7 EJECUTA 73 SIG.
      LEER DISCO DOCSIS TOT-NUM-PRO
      TOT-PRO-SIS = TOT-PRO-SIS + TOT-NUM-PRO
      EJECUTA 72
73    ESCRIBIR TERMINAL NUM-SIS NOM-SIS TOT-PRO-SIS
      SI TOT-PRO-SIS <> 0 EJECUTA 71
      MOVER 'SE BORRO' A BORRADO
      ESCRIBIR TERMINAL BORRADO
      BORRAR RECURRENTE DOCSIS 6
      IND-BOR  =  1
      EJECUTA 71
*
 74   SI  IND-BOR  =  0  EJECUTA  76
      OPCION  TERMINAL  AREA  308                             $
      /PROCESADA   /SALVAR-ANTERIORES  /DESPLEGAR  /EMPALMAR
      ESCRIBIR  TERMINAL   GPO-SIS-M1
      OPCION TERMINAL  AREA  308  /TERMINAR
*
  76  OPCION  TERMINAL  AREA  324  /TERMINAR
      OPCION  TERMINAL  AREA  306  /TERMINAR
      EJECUTA 1
*
*    ERRORES
*
 90   ERROR 'ERROR 1 EN PSDCEC' 'ERROR AL CONVERTIR EN 11 o 12'
      FIN
92    ERROR 'ERROR 1 EN PSDCEC' 'ERROR EN CONVERTIR EN 32'
      FIN
93    ERROR 'ERROR 1 EN PSDCEC' 'NO SE ENCONTRO DBD'
      FIN
 999  FIN 'DCME'
*
 1000 FIN
