* PSDCE1
*D
*D    ESTE PROGRAMA DESPLIEGA EL USO DE LOS DIFERENTES MODULOS
*D    DE SISINF EN LOS DIFERENTES MESES, POR UN USUARIO.
*D
*     DEFINIR AREAS PARA PREGUNTAR POR USUARIO
*- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      PROGRAMA 'INFORMACION DE UN USUARIO'
      DOCUMENTACION  2  0
      OPCION TERMINAL AREA 100 /RENGLON /POS. 5 5 /LONG. 7 70 $
      /MARCO /BN NO-E VI NO-E $
      /COLOR AMARILLO AMARILLO NEGRO AZUL BLANCO $
      /TECLAS-DE-FUNCION 1 'TERMINAR  ELS' 2 'MENU CON' 3 '? AYUDA' $
      /CONDICION-EJECUTA '/F' '/M' $
      /INF-GLOBAL /TAB. 5 45 /CAMPOS 3 5 PREUS PRE-NUM-CA TOI
*
      OPCION TERMINAL AREA 101 /COLUMNA 3 /POS. 9 20 /LONG. 11 60 $
      /MARCO /COLOR CELESTE CELESTE NEGRO /BN VI NO-E $
      /CAMPOS 'NUMERO' NUM-CA /ESC. /VAR. NOM-US /ESC.
*
      OPCION TERMINAL AREA 102 /RENGLON 1 1 /POS. 11 5 /LONG. 8 70 $
      /MARCO /COLOR CELESTE CELESTE NEGRO /CONFIRMAR /CAMPOS $
      2 3 'Esta opcion sirve para desplegar' $
          'o imprimir el uso de los' $
      3 3 'modulos de SISINF por un' $
          'usuario del mismo.' $
      4 3 '-Contestar SI a la PRIMER pregunta' $
          'ocacionara se despliegen los' $
      5 4 'numeros y nombres de los' $
          'usuarios para seleccionar uno.' $
      6 3 '-La SEGUNDA pregunta se debe contestar' $
          'con el numero del usuario.' $
      7 3 '-Se pueden desplegar los datos por' $
          'Terminal o bien Imprimir.'
*D
*D    PREGUNTAR SI SE DESPLIEGAN LOS DIFERENTES USUARIOS QUE HAY
*D    PARA ELLO SE RECORRE EL R0 EN FORMA SECUENCIAL Y SE
*D    DESPLIEGA SU CONTENIDO.
*
1     OPCION TERMINAL AREA 100 /DESPLEGAR
      LEER TERMINAL EJECUTA 20 PREUS
      SI PREUS = 'NO' EJECUTA 5
      OPCION TERMINAL AREA 101 /DESPLEGAR /SALVAR-ANTERIORES $
         /EMPALMAR
2     BUSCAR DISCO SIUS EJECUTA 3 SEC-G1
      LEER DISCO SIUS NUM-CA NOM-US AREA
      ESCRIBIR TERMINAL NUM-CA NOM-US
      EJECUTA 2
3     OPCION TERMINAL AREA 101 /TERMINAR
*D
*D    LEER NUMERO DE CLAVE DE ACCESO Y REVISA QUE EXISTA
*
5     LEER TERMINAL EJECUTA 20 PRE-NUM-CA
      NUM-CA = PRE-NUM-CA
      BUSCAR DISCO SIUS EJECUTA 6 PRIN-G1 NUM-CA
      LEER DISCO SIUS NOM-US AREA
      EJECUTA 10
6     ERROR 'NO EXISTE' NUM-CA
      EJECUTA 5
*D
*D    PREGUNTA POR TERMINAL o IMPRESORA
*
10    LEER TERMINAL EJECUTA 20 TOI
      SI TOI = 'T' EJECUTA 50
      SI TOI = 'I' EJECUTA 30
      ERROR 'NO TECLEO T O I'
      EJECUTA 10
*D
*D    INVESTIGAR EJECUTA #
*
20    SACAR PARAMETROS CONDICION-EJECUTA COND
      SI COND = -1 EJECUTA 1000
      SI COND = 1  EJECUTA 1000
      SI COND = -4 EJECUTA 1000
      SI COND = 2  EJECUTA 999
      SI COND = -5 EJECUTA 999
      OPCION TERMINAL AREA 102 /DESPLEGAR /SALVAR-ANTERIORES /EMPALMAR
      OPCION TERMINAL AREA 102 /TERMINAR
      EJECUTA 1
*D
*D    IMPRIMIR LA INFORMACION ORDENANDO EL R1 POR MES Y MODULO
*
30    OPCION IMPRIMIR  COL. 80 LET. 'USO DE SISINF POR UN USUARIO' $
      FECHA FEC ENC. 2 GUION40 42 GUION40 $
      ENC. 1 '0' 2 NUM-CA  30 NUM-CA VAR.  35 NOM-US VAR. $
      ENC. 35 AREA VAR.     $
      ENC. 1 '0' 2 AMES 6 NUM-MOD 15 MIN-REL 30 SEG-CPU 45 TOT-EJE $
      57 EJE-ERR 70 PAG-IMP  $
      ENC. 2 GUION40 42 GUION40
      SACAR PARAMETROS FECHA FEC
*
31    OPCION DISCO SIUS ORD-R1 A AMES A NUM-MOD
32    BUSCAR RECURRENTE SIUS 1 EJECUTA 999 ORD.
      LEER DISCO SIUS AMES NUM-MOD SEG-RELOJ SEG-CPU TOT-EJE $
            EJE-ERR PAG-IMP
      CONVERTIR AMES A MES POS. 3 3 EJECUTA 35
      CONVERTIR AMES A MES POS. 4 4 EJECUTA 35
      BUSCAR TABLA TMESES EJECUTA 36 IGUAL MES MES-ALFA
      BUSCAR TABLA MODSIS EJECUTA 37 IGUAL NUM-MOD MOD-ALFA
      MIN-REL = SEG-RELOJ / 60
      IMPRIMIR DETALLE 2 MES-ALFA 6 MOD-ALFA 15 MIN-REL   $
       30 SEG-CPU  45 TOT-EJE 55 EJE-ERR 70 PAG-IMP
      EJECUTA 32
35    ERROR 'ERROR 1 EN PSDCE1' 'ERROR AL CONVERTIR'
      FIN
36    ERROR 'ERROR 4 EN PSDCE1' 'NO ESTA EN TABLA TMESES'
      FIN
37    ERROR 'ERROR 4 EN PSDCE1' 'NO ESTA EN TABLA MODSIS'
      FIN
*D
*D    DEFINIR EL AREA PARA DESPLEGARLOS Y USAR LA MISMA
*D    LOGICA DE IMPRESION.
*
      OPCION TERMINAL AREA 103 /RENGLON /POS. 5 5 /LONG. 5 70 $
      /MARCO /COLOR CELESTE CELESTE NEGRO /BN NO-E VI /TAB. 3 30 $
       /CAMPOS NUM-CA /ESC. NOM-US /ESC. /LONG. 38 4 30 AREA /VAR. $
             /LONG. 38
      OPCION TERMINAL AREA 104 /COLUMNA 2 /POS. 10 5 /LONG. 10 70 $
      /MARCO /COLOR AMARILLO AMARILLO NEGRO /BN VI NO-E NO-E $
      /CAMPOS 'MES' MES-ALFA /ESC. /VAR. 'MODULO' MOD-ALFA /ESC.  $
       /VAR. MIN-REL /ESC. SEG-CPU /ESC. $
          TOT-EJE /ESC. EJE-ERR /ESC. /VAR. PAG-IMP /ESC.
50    OPCION TERMINAL AREA 103 104 /DESPLEGAR
      ESCRIBIR TERMINAL NUM-CA NOM-US AREA
      OPCION DISCO SIUS ORD-R1 A AMES A NUM-MOD
51    BUSCAR RECURRENTE SIUS 1 EJECUTA 52 ORD.
      LEER DISCO SIUS AMES NUM-MOD SEG-RELOJ SEG-CPU TOT-EJE $
            EJE-ERR PAG-IMP
      CONVERTIR AMES A MES POS. 3 3 EJECUTA 35
      CONVERTIR AMES A MES POS. 4 4 EJECUTA 35
      BUSCAR TABLA TMESES EJECUTA 36 IGUAL MES MES-ALFA
      BUSCAR TABLA MODSIS EJECUTA 37 IGUAL NUM-MOD MOD-ALFA
      MIN-REL = SEG-RELOJ / 60
      ESCRIBIR TERMINAL MES-ALFA MOD-ALFA MIN-REL   $
       SEG-CPU  TOT-EJE EJE-ERR PAG-IMP
      EJECUTA 51
52    OPCION TERMINAL AREA 103 104 /TERMINAR
*
999   FIN 'DCE0'
1000  FIN
