* PSDCE0
*
*  CONTABILIDAD DE SISINF
*
* ---------------------------------------------------------------
      PROGRAMA 'MENU DE USO DE SISINF'
      DOCUMENTACION 2 0  EST-USO
*D
*D    ESTE PROGRAMA ES EL MENU DEL SISTEMA USO DE SISINF.
*
      IGUAL AREA X4 OPCION
      OPCION TERMINAL AREA 10     /MENU  5  1  0         /MARCO      $
      /TECLAS-DE-FUNCION   1 'TERMINAR'   3 '? AYUDA'                $
      /BN   VI    VI     NORMAL                                      $
      /COLOR   BLANCO   BLANCO AZUL   AMARILLO NEGRO   BLANCO NEGRO  $
*
      /CAMPOS     'OPCIONES DE SISTEMA DE USO DE SISINF   ' /ENC.    $
      'DCE1'   5  'INFORMACION DE UN USUARIO              '          $
      'DCE2'   5  'LISTADO DE USUARIOS                    '          $
      'DCE3'   5  'ACTUALIZACION DE SIUS                  '          $
      'DCE4'   5  'ACTUALIZACION Y REPORTE DE USO         '          $
         '1'   5  'ACTUALIZACION EN BATCH                 '          $
      'DCE5'   5  'CONSUMO DE CPU                         '          $
      'DCE6'   5  'ESTADISTICAS DE USO                    '          $
                  'A Y U D A S                            ' /ENC-OP. $
         '2'      'EXPLICACION CONTABILIDAD DE USO (IMP.) '          $
         '3'      'EXPLICACION ESTADISTICAS DE USO (IMP.) '          $
         '4'      'EXPLICACION CONTABILIDAD DE USO (TERM.)'          $
         '5'      'EXPLICACION ESTADISTICAS DE USO (TERM.)'          $
         '6'      'TERMINAR.                              '          $
      OPCION     /VAR-SEL.
*
      OPCION TERMINAL AREA 11 /RENGLON 1 1 /POS. 7 10 $
      /LONG. 7 60 /MARCO /COLOR CELESTE CELESTE NEGRO   $
      /CONFIRMAR 'TECLEE RETURN PARA SELECCIONAR OPCION' /CAMPOS $
           2 3 'Se tienen las diferentes opciones' $
               'del Sistema de' $
           3 3 'Contablidad de Uso de' $
               'SISINF y Estadisticas.' $
           4 3 'Es necesario se seleccione una,' $
               'recordando que al inicio' $
           5 3 'de cada OPCION se puede dar ?' $
               'o F3 para una explicacion.' $
           6 3 'Para algunas opciones ver' $
               'Explicacion.'
*
10    OPCION TERMINAL AREA 10 /DESPLEGAR
11    LEER TERMINAL EJECUTA 12 OPCION
      OPCION TERMINAL AREA 10 /TERMINAR
      SI OPCION = '1' EJECUTA   20
      SI OPCION = '2' EJECUTA   30
      SI OPCION = '3' EJECUTA   40
      SI OPCION = '4' EJECUTA   50
      SI OPCION = '5' EJECUTA   60
      SI OPCION = '6' EJECUTA 1000
      FIN OPCION
12    SACAR PARAMETROS CONDICION-EJECUTA COND
      SI COND =  1 EJECUTA 1000
      SI COND = -1 EJECUTA 1000
      OPCION TERMINAL AREA 11 /DESPLEGAR /SALVAR-ANTERIORES /EMPALMAR
      OPCION TERMINAL AREA 11 /TERMINAR
      EJECUTA 11
*---------------------------------------------------------------------
*D
*D    LLAMAR A PSDCE4 EN BATCH
*--------------------------------------------------------------------
20    OPCION TEMPORAL 950   ESCRITURA   ASCII
      ESCRIBIR  TEMPORAL  950  '*C *INICIO*'
      ESCRIBIR  TEMPORAL  950  '*M ELS-C,DC,E4,C:\SISINF\DSIS'
      ESCRIBIR  TEMPORAL  950  '*C *FIN*'
      LLAMAR    'SIS/B '  950
      EJECUTA 10
*D
*D    PARA LISTAR LAS EXPLICACIONES SE SACA LA INFORMACION DE LOS
*D    TEMPORALES T704 Y T705.
*
30    OPCION IMPRIMIR LET. 'EXPLICACION CONTABILIDAD DE USO' COL. 80
      OPCION    TEMPORAL  704 LECTURA ASCII DISCO 'C:\SISINF\DSIS'
32    LEER      TEMPORAL  704 EJECUTA 10 X40 X30 X10
      IMPRIMIR  DETALLE    5  X40      45 X30
      EJECUTA 32
*
40    OPCION IMPRIMIR LET. 'EXPLICACION ESTADISTICAS DE USO' COL. 80
      OPCION TEMPORAL 705 LECTURA ASCII DISCO 'C:\SISINF\DSIS'
41    LEER TEMPORAL 705 EJECUTA 10 X40 X30 X10
      IMPRIMIR DETALLE 5 X40 45 X30
      EJECUTA 41
*
*D
*D    DEFINIR LAS AREAS PARA DESPLEGAR EXPLICACIONES
*
      OPCION  TERMINAL  AREA  12  /COLUMNA    /MARCO                 $
      /POS.  3  2        /LONG.  15  74                              $
      /BN     VI    NORMAL    NORMAL                                 $
      /COLOR    BLANCO    BLANCO AZUL                                $
*
      /CAMPOS                                                        $
       2 21 'Explicacion Contablidad de Uso.'                        $
       3 3 X40 /VAR. /ESC.  3 43 X30 /ESC. /VAR.
*
50    OPCION    TERMINAL       AREA 12 /DESPLEGAR
      OPCION    TEMPORAL  704  LECTURA ASCII DISCO 'C:\SISINF\DSIS'
51    LEER      TEMPORAL  704  EJECUTA 52 X40 X30 X10
      ESCRIBIR  TERMINAL  X40  X30
      EJECUTA 51
52    OPCION TERMINAL AREA 12 /TERMINAR
      EJECUTA 10
*
*    EXPLICACION ESTADISTICA DE USO
*
      OPCION TERMINAL AREA 13   /COLUMNA     /MARCO                  $
      /POS.  5  2   /LONG.  15   74                                  $
      /BN      VI   NORMAL    NORMAL                                 $
      /COLOR   BLANCO      BLANCO AZUL                               $
      /CAMPOS                                                        $
      2 21  'Explicacion Estadisticas de Uso.'                       $
      3  3  X40 /ESC. /VAR.         3 43 X30 /VAR. /ESC.
*
*  esplicacion de estadistica de uso por  terminal
*
 60   OPCION    TEMPORAL 705 LECTURA ASCII DISCO 'C:\SISINF\DSIS'
      OPCION    TERMINAL      AREA   13   /DESPLEGAR
*
 61   LEER      TEMPORAL 705 EJECUTA 62 X40 X30 X10
      ESCRIBIR  TERMINAL   X40   X30
      EJECUTA 61
*
62    OPCION TERMINAL AREA 13 /TERMINAR
      EJECUTA 10
*
1000  FIN
