* PSDCGA
      PROGRAMA 'FORMAR T800'
      DOCUMENTACION 1 5
*D
*D    ESTE PROGRAMA SIRVE PARA GENERAR UN TEMPORAL T800 PAR QUE SE 
*D    SE PASE JUNTO CON LOS PROGRAMAS A OTRA MAQUINA Y ASI SE
*D    PUEDAN COMPLILAR TODOS LOS PROGRAMAS DE UNA DBD
*D
*D    SE LEEN LAS INCIALES DE DBD Y SE DESPLIEGA EL DISPOSITIVO,
*D    LA FECHA DE ULTIMA ACTUALIZACION DEL R15.
*
      OPCION TERMINAL AREA  200  /RENGLON   /POS. 5 3   /LONG. 11 74 $
      /MARCO                     /TAB.  3 40     /TIEMPO  0  5       $
      /TECLAS-DE-FUNCION 1 'TERMINAR ELS'  2 'MENU DOC'  3 '? AYUDA' $
      /CONDICION-EJECUTA   '/F'   '/M'                               $
      /BN  NORMAL     VI    NORMAL                                   $
      /COLOR   CELESTE    CELESTE NEGRO    BLANCO AZUL   AZUL BLANCO $
*
      /CAMPOS 3 3 INI-DBD DIS-DBD /ESC. FEC-ACT /ESC.  HOR-ACT /ESC. $
              9 3 TOT-COMP /ESC.
*
      OPCION TERMINAL AREA 201 /RENGLON 1 1 /POS. 13 5  $
      /LONG. 5 70 /MARCO /COLOR AMARILLO AMARILLO NEGRO  $
      /CONFIRMAR /CAMPOS $
           2 3 'Esta opcion sirve para generar T800' $
               'con las iniciales de' $
           3 3 'los programas que formar la DBD.' $
           4 3 'Se debe contestar con las iniciales' $
               'de DBD cuyo temporal se forma.' 
*
      OPCION TERMINAL AREA 999 /ERROR $
       /COLOR NEGRO NEGRO BLANCO
*
      OPCION TERMINAL AREA 200 /DESPLEGAR
1     LEER TERMINAL EJECUTA 20 INI-DBD
      BUSCAR DISCO DOCSIS EJECUTA 3 PRIN-G1 INI-DBD
      LEER DISCO DOCSIS DIS-DBD
      ESCRIBIR TERMINAL DIS-DBD
      BUSCAR RECURRENTE DOCSIS 15 EJECUTA 2  SUP.
      LEER DISCO DOCSIS FEC-ACT HOR-ACT
      ESCRIBIR TERMINAL  FEC-ACT HOR-ACT
      EJECUTA 50
2     ERROR 'ERROR 2 EN PSDCGA' 'NO EXISTE FECHA DE ACTUALIZACION'
      FIN
3     ERROR 'DBD INEXISTENTE'
      EJECUTA 1
*
*     AYUDA Y TF
*
20    SACAR PARAMETROS CONDICION-EJECUTA COND
      SI COND = 1 EJECUTA 1000
      SI COND = -1 EJECUTA 1000
      SI COND = -4 EJECUTA 1000
      SI COND = -5 EJECUTA 999
      SI COND = 2 EJECUTA 999
      OPCION TERMINAL AREA 201 /DESPLEGAR /SALVAR-ANTERIORES /EMPALMAR
      OPCION TERMINAL AREA 201 /TERMINAR
      EJECUTA 1
*D
*D    SE RECORRE EL R6 PARA IR COMPILANDO POR SISTEMAS,
*D    SE RECORRE EL R7 PARA IR COMPILANDO POR GRUPOS,
*D    SE RECORRE EL R8 PARA SACAR INFORMACION DEL PROGRAMA
*D    A COMPILAR Y SE PASA AL T800
*
50    OPCION TEMPORAL 800 ESCRITURA ASCII
      MOVER ' ' A RELLENO-T800-DBD
      MOVER ' ' A RELLENO-T800-CLS
      ESCRIBIR TEMPORAL 800 'DBDS' INI-DBD DIS-DBD RELLENO-T800-DBD
      TOT-COMP = 0
52    BUSCAR RECURRENTE DOCSIS 6 EJECUTA 60 ANT.
53    BUSCAR RECURRENTE DOCSIS 7 EJECUTA 52 ANT.
54    BUSCAR RECURRENTE DOCSIS 8 EJECUTA 53 ANT.
      LEER DISCO DOCSIS NOM-PRO DIS-PRO NOM-PRO-EXT
      ESCRIBIR TEMPORAL 800 NOM-PRO DIS-PRO NOM-PRO-EXT $
                            RELLENO-T800-CLS
      TOT-COMP = TOT-COMP + 1
      EJECUTA 54
60    OPCION TEMPORAL 800
      ESCRIBIR TERMINAL TOT-COMP
      OPCION TERMINAL AREA 200 /TERMINAR 
999   FIN 'DCME'
1000  FIN
