* PSDCF6
       PROGRAMA 'BUSCAR PALABRAS'  DIR  /COLOR BLANCO AZUL 
       DOCUMENTACION 3 0
       SI DIR-PER-TEM = ' ' EJECUTA 1
       OPCION DISCO AYUDAA DISCO DIR-PER-TEM
       OPCION DISCO AYUDAV DISCO DIR-PER-TEM
       OPCION DISCO AYUDAP DISCO DIR-PER-TEM
*
*D    ESTE PROGRAMA BUSCA PALABRAS EN LOS ARCHIVOS DE AYUDAS
*D
*     DEFINIR AREA DE PALABRA
*
      IGUAL AREA NUMERO-DE-AYUDA NUM-AYUDA-A 
      IGUAL AREA NUMERO-DE-AYUDA NUM-AYUDA-V 
      IGUAL AREA NUMERO-DE-AYUDA NUM-AYUDA-P 
      OPCION TERMINAL AREA 1 /RENGLON /MARCO $
      /COLOR CELESTE CELESTE NEGRO NEGRO AMARILLO BLANCO NEGRO $
       /TECLAS-DE-FUNCION 1 'TERMINAR' 2 '*AYUDA' 3 'MENU' $
       /AYUDA-GLOBAL DESPLEGAR-AYUDA /POS. 2 10 /LONG. 4 60 $
       /BN NO-E VI NO-E /CAMPOS  PAL-BUSC $
       3  3 '# EN AYUDAA' NUM-AYUDA-A /VAR. $
       3 21 '# EN AYUDAP' NUM-AYUDA-P /VAR. $
       3 39 '# EN AYUDAV' NUM-AYUDA-V /VAR. 
*
      OPCION TERMINAL AREA 2 /TEXTO /MARCO /POS. 7 10 /LONG. 12 60 $
      /COLOR CELESTE CELESTE NEGRO  $
      /TECLAS-DE-FUNCION 1 'TERMINAR' 3 'MENU' $
      /CAMPOS INF-BUSCAR /VAR. /ESC.
*
*     DESPLEGAR AREAS Y LEER SELECCION
*
1     OPCION TERMINAL AREA 1 2 /DESPLEGAR
      LEER TERMINAL EJECUTA 50 PAL-BUSC
      FORMAR TEXTO INF-BUSCAR CON 'La palabra "' /S /INICIO
      FORMAR TEXTO INF-BUSCAR CON PAL-BUSC
      FORMAR TEXTO INF-BUSCAR CON '" se busca en los archivos $
               $de ayuda de SISINF'
*
*     BUSCAR EN AYUDAV
*
      NUMERO-DE-AYUDA = 0
      NUM-AYUDA-V = 0
      OPCION DISCO AYUDAV INICIO-G1
11    BUSCAR DISCO AYUDAV EJECUTA 20 SEC-G1
      LEER DISCO AYUDAV NOM-VAR INI-PRO TEXTO-AYUDA
      SI PAL-BUSC =P TEXTO-AYUDA EJECUTA 12
      EJECUTA 11
12    NUMERO-DE-AYUDA = NUMERO-DE-AYUDA + 1
      NUM-AYUDA-V = NUM-AYUDA-V + 1
      FORMAR TEXTO INF-BUSCAR CON 20'* /C /RBA 1
      FORMAR TEXTO INF-BUSCAR CON NUMERO-DE-AYUDA /JD
      FORMAR TEXTO INF-BUSCAR CON 'Se encuentra en AYUDAV, $
              $para la variable ' /S
      FORMAR TEXTO INF-BUSCAR CON NOM-VAR
      SI INI-PRO = ' ' EJECUTA 13
      FORMAR TEXTO INF-BUSCAR CON ' del programa '
      FORMAR TEXTO INF-BUSCAR CON INI-PRO
13    FORMAR TEXTO INF-BUSCAR CON ' La ayuda es: '
      FORMAR TEXTO INF-BUSCAR CON TEXTO-AYUDA
      EJECUTA 11
*
*     BUSCAR EN AYUDAA
*
20    NUM-AYUDA-A = 0
      OPCION DISCO AYUDAA INICIO-G1
21    BUSCAR DISCO AYUDAA EJECUTA 30 SEC-G1
      LEER DISCO AYUDAA NUM-AREA INI-PRO TEXTO-AYUDA
      SI PAL-BUSC <>P TEXTO-AYUDA EJECUTA 21
      NUMERO-DE-AYUDA = NUMERO-DE-AYUDA + 1
      NUM-AYUDA-A = NUM-AYUDA-A + 1
      FORMAR TEXTO INF-BUSCAR CON 20'* /C /RBA 1
      FORMAR TEXTO INF-BUSCAR CON NUMERO-DE-AYUDA /JD
      FORMAR TEXTO INF-BUSCAR CON 'Se encuentra en AYUDAA, $
              $para el area ' /S
      FORMAR TEXTO INF-BUSCAR CON NUM-AREA
      SI INI-PRO = ' ' EJECUTA 22
      FORMAR TEXTO INF-BUSCAR CON ' del programa '
      FORMAR TEXTO INF-BUSCAR CON INI-PRO
22    FORMAR TEXTO INF-BUSCAR CON ' La ayuda es: '
      FORMAR TEXTO INF-BUSCAR CON TEXTO-AYUDA
      EJECUTA 21
*
*     BUSCAR EN AYUDAP
*
30    NUM-AYUDA-P = 0
      OPCION DISCO AYUDAP INICIO-G1
31    BUSCAR DISCO AYUDAP EJECUTA 40 SEC-G1
      LEER DISCO AYUDAP INI-PRO TEXTO-AYUDA
      SI PAL-BUSC <>P TEXTO-AYUDA EJECUTA 31
      NUMERO-DE-AYUDA = NUMERO-DE-AYUDA + 1
      NUM-AYUDA-P = NUM-AYUDA-P + 1
      FORMAR TEXTO INF-BUSCAR CON 20'* /C /RBA 1
      FORMAR TEXTO INF-BUSCAR CON NUMERO-DE-AYUDA /JD
      FORMAR TEXTO INF-BUSCAR CON 'Se encuentra en AYUDAP, $
              $para el programa ' /S
      FORMAR TEXTO INF-BUSCAR CON INI-PRO
      FORMAR TEXTO INF-BUSCAR CON ' La ayuda es: '
      FORMAR TEXTO INF-BUSCAR CON TEXTO-AYUDA
      EJECUTA 31
*
*     TERMINAR
*
      IGUAL AREA N1 COND-E
40    ESCRIBIR TERMINAL NUM-AYUDA-A NUM-AYUDA-V NUM-AYUDA-P
      ESCRIBIR TERMINAL INF-BUSCAR
      OPCION TERMINAL AREA 1 2 /TERMINAR
      SACAR PARAMETROS CONDICION-TERMINAR COND-E
      SI COND-E = 0 EJECUTA 1
      SI COND-E = 3 FIN 'DCF0'
      FIN
50    SACAR PARAMETROS CONDICION-EJECUTA COND-E
      SI COND-E = 3 FIN 'DCF0'
      FIN
*
*     INCLUIR RUTINAS DE AYUDA
*
&I AYUP
