PROGRAMA 'Imagenes, graficas, ..'
*
* Este programa ilustra el uso de una imagenes, graficas y
* figuras convinadas en una sola imagen.
*
* Para ello se saca primero una imagen cargada con el programa
* PSSIB3, se le pone un texto, se le agrega una grafica y
* otra imagen cargada con el mismo programa.
*
IGUAL AREA N10 DIM-X DIM-X2 DIM-X3 DIM-2X3 DIM-Y DIM-Y2 DIM-Y3
IGUAL IMA FOTO-1 IMA-CON
*
OPCION TERMINAL AREA 10 /IMAGEN /MARCO /BN VI $
/COLOR BLANCO BLANCO NEGRO /CONFIRMAR $
/POS. 2 10 /LONG. 20 60 /CAMPOS 2 2 IMA-CON /VAR. /ESC. $
/LONG. 58 /RENG. 18
*
BUSCAR DISCO IMA EJECUTA 90 SEC-G1
LEER DISCO IMA FOTO-1
BUSCAR DISCO IMA EJECUTA 90 SEC-G1
LEER DISCO IMA FOTO-2
*
* Iniciar IMA-CON con las medidas del area
*
FORMAR IMAGEN IMA-CON /INICIO 0 0 'BLANCO' $
/MEDIDA-AREA 10 DIM-X DIM-Y /X-Y-GRAFICO
DIM-X2 = DIM-X / 2
DIM-Y2 = DIM-Y / 2
DIM-X3 = DIM-X / 3
DIM-2X3 = DIM-X3 + DIM-X3
DIM-Y3 = DIM-Y / 3
*
* Pasar la imagen
*
FORMAR IMAGEN IMA-CON /EMPALMAR 0 0 0 0 FOTO-1 0
*
* Poner el texto
*
FORMAR IMAGEN IMA-CON /EFECTO-LINEAS 'LLENO' 50 $
/TEXTO DIM-X2 50 'C-M' 'Graficas' $
'SU-NR' 90 0 'TRANSPARENTE' 'AZUL' 'ROMBOS' 'ROJO'
* FORMAR IMAGEN IMA-CON /EFECTO-LINEAS 'LLENO' 50 $
* /TEXTO DIM-X2 50 'C-M' 'Graficas' $
* 'SU-NR' 90 0 'TRANSPARENTE' 'NEGRO' 'LLENO' 'TRANSPARENTE'
*
* Agregar una grafica
*
FORMAR IMAGEN IMA-CON /GRAFICA-BARRAS $
/NO-LETREROS /NO-VALORES /2D $
/POSICION-MEDIDAS 20 DIM-Y2 DIM-X2 DIM-Y2 $
/DATO 10 '1' 'ROJO' $
/DATO 25 '2' 'AMARILLO' $
/DATO 18 '3' 'GRIS' $
/DATO 14 '4' 'VERDE' $
/CONSTRUIR
*
* Poner segunda foto
*
FORMAR IMAGEN IMA-CON /EMPALMAR DIM-2X3 DIM-Y3 DIM-X3 DIM-Y3 $
FOTO-2 0
*
* Desplegar
*
OPCION TERMINAL AREA 10 /DESPLEGAR
ESCRIBIR TERMINAL IMA-CON
OPCION TERMINAL AREA 10 /TERMINAR
*
* Cortar y desplegar
*
DIM-X = DIM-X - 40
DIM-Y = DIM-Y - 40
FORMAR IMAGEN IMA-CON /CORTAR 20 20 DIM-X DIM-Y
OPCION TERMINAL AREA 10 /DESPLEGAR
ESCRIBIR TERMINAL IMA-CON
OPCION TERMINAL AREA 10 /TERMINAR
*
* Escribir en temporal
*
OPCION TEMPORAL 900 /NOMBRE 'ima.png' /DISCO 'c:' $
/INTERNET /EXTERNO /ESCRITURA
ESCRIBIR TEMPORAL 900 IMA-CON
OPCION TEMPORAL 900
*
OPCION TEMPORAL 901 /NOMBRE 'ima.png' /DISCO 'c:' $
/INTERNET /EXTERNO /LECTURA
LEER TEMPORAL 901 EJECUTA 90 IMA-CON
OPCION TEMPORAL 901
*
OPCION TERMINAL AREA 10 /DESPLEGAR
ESCRIBIR TERMINAL IMA-CON
OPCION TERMINAL AREA 10 /TERMINAR
*
90 FIN