PROGRAMA 'Actualiza Mapas' /COLOR GRIS NEGRO
*
* Este programa actualiza el archivo MAPAS pero la asignacion
* de los numeros de mapa es interna y el proceso de marcado
* es diferente ya que primero se dan los datos de la marca
* y luego se marca la imagen.
*
IGUAL AREA N10 OP-SEL TOT-MAPAS TOT-FALTA TOT-CAM $
SUB SUBM IND-1L COLOR TIPO-MARCA $
DIM-MARCA COLOR-F COLOR-M SUBA TOT-MAR
IGUAL AREA N20 CAR-IMA
IGUAL AREA X30 DESC
IGUAL AREA X60 DESC-ERR
IGUAL MAPAS NUM-MAPA NUM-MAPA-V NUM-MAPA-VX
IGUAL MAPAS NOM-MAPA NOM-MAPA-V NOM-MAPA-VX
IGUAL MAPAS NUM-MARCA NUM-MARCA-V
IGUAL MAPAS DES-MARCA DES-MARCA-V
VECTOR NUM-MAPA-V RANGO-EXTENDIDO 1 1000
VECTOR NUM-MAPA-VX RANGO-EXTENDIDO 1 1000
VECTOR NOM-MAPA-V RANGO-EXTENDIDO 1 1000
VECTOR NOM-MAPA-VX RANGO-EXTENDIDO 1 1000
VECTOR NUM-MARCA-V RANGO-EXTENDIDO 1 1000
VECTOR DES-MARCA-V RANGO-EXTENDIDO 1 1000
*
* Area de error
*
OPCION TERMINAL AREA 5 /RENGLON /MARCO /POS. 19 5 $
/LONG. 3 70 /BN NORMAL VI VI $
/COLOR ROJO ROJO BLANCO /CONFIRMAR $
/CAMPOS DESC-ERR /VAR. /ESC.
*
* Area del menu de opciones
*
OPCION TERMINAL AREA 10 /MENU /MARCO /POS. 1 1 $
/COLOR AZUL AZUL BLANCO-B AMARILLO AZUL AZUL BLANCO-B $
/TECLAS-DE-FUNCION 1 'Terminar' $
/LONG. 10 34 /BN NO-E VI NO-E /CAMPOS $
1 'Agregar imagen mapa' $
2 'Agregar marca' $
3 'Modificar imagen mapa' $
4 'Modificar desc. marcas' $
5 'Cambiar marca' $
6 'Quitar imagen mapa' $
7 'Quitar marca' $
8 'Revisar' $
OP-SEL /VAR-SEL.
*
* Area para nombre del mapa
*
OPCION TERMINAL AREA 12 /RENGLON /BN CI VI NO-E $
/COLOR BLANCO BLANCO NEGRO NEGRO AMARILLO CELESTE NEGRO $
/TECLAS-DE-FUNCION 4 'Cancelar' $
/MARCO /POS. 1 44 /LONG. 4 36 $
/CAMPOS 2 3 'De el nombre del mapa principal' $
3 3 NOM-MAPA /VAR. /LEC. /INF.
*
* Area para leer, modificar y escribir la imagen del mapa
*
OPCION TERMINAL AREA 14 /IMAGEN /BN VI $
/COLOR BLANCO BLANCO NEGRO $
/MARCO /POS. 12 22 /LONG. 10 36 $
/CONFIRMAR /CONFIRMAR-1 /CONFIRMAR-2 $
/CAMPOS 2 3 IMA-MAPA /VAR. /LEC. /LONG. 32 /RENG. 8 $
/MOD-1 /ESC-2
*
* Seleccionar los mapas
*
OPCION TERMINAL AREA 16 /MENU 3 0 0 $
/POS. 1 40 /LONG. 10 40 /BN NORMAL VI VI /MARCO $
/COLOR NEGRO NEGRO BLANCO-B BLANCO AZUL NEGRO BLANCO-B $
/TECLAS-DE-FUNCION 4 'Cancelar' /CAMPOS $
'Seleccione' /ENC. DESC SUB /VAR-SEL.
*
* Area para leer una marca
*
OPCION TERMINAL AREA 20 /RENGLON /BN VI $
/TECLAS-DE-FUNCION 4 'Cancelar' $
/COLOR BLANCO BLANCO NEGRO GRIS BLANCO-B BLANCO NEGRO $
/MARCO /POS. 12 1 /LONG. 10 36 $
/CAMPOS 2 3 'Descripcion de la marca' $
3 3 DES-MARCA /VAR. /LEC. $
5 3 'Es liga a otro mapa ' $
6 3 OTRO-MAPA /VAR. /LEC. /DESP-LEC. $
8 3 'Numero de planta' $
9 3 NUM-MARCA /VAR. /LEC.
*
* Area para leer la marca
*
OPCION TERMINAL AREA 22 /IMAGEN /BN VI $
/COLOR BLANCO BLANCO NEGRO /CONFIRMAR $
/AGREGAR-MARCA NUM-MARCA 'ROMBO' 20 'AMARILLO' 'AMARILLO' $
/MARCO /POS. 12 44 /LONG. 10 36 $
/CAMPOS 2 3 IMA-MAPA /VAR. /MOD. /LONG. 32 /RENG. 8
*
* Area para modificar las descripciones de marcas
*
OPCION TERMINAL AREA 24 /COLUMNA /BN VI $
/COLOR BLANCO BLANCO NEGRO $
/MARCO /POS. 12 18 /LONG. 10 44 $
/CAMPOS 2 3 'Modifique descripcion' $
2 3 DES-MARCA /VAR. /MOD.
*
* Area para pedir se vuelva a marcar
*
OPCION TERMINAL AREA 26 /RENGLON /BN VI $
/COLOR BLANCO BLANCO NEGRO /CONFIRMAR $
/MARCO /POS. 12 1 /LONG. 5 40 $
/CAMPOS 2 3 'Se modifico imagen' $
3 3 'Se debe marcar:' $
4 4 DES-MARCA /VAR. /ESC.
*
* Seleccionar las marcas
*
OPCION TERMINAL AREA 30 /MENU 3 0 0 $
/POS. 12 25 /LONG. 10 50 /BN NORMAL VI VI /MARCO $
/COLOR NEGRO NEGRO BLANCO-B BLANCO AZUL NEGRO BLANCO-B $
/TECLAS-DE-FUNCION 4 'Cancelar' /CAMPOS $
'Seleccione' /ENC. DES-MARCA NUM-MARCA OTRO-MAPA $
SUBA /VAR-SEL.
*
* Menu de tipos de marcas
*
OPCION TERMINAL AREA 32 /MENU 3 0 0 /MARCO /POS. 1 1 $
/COLOR AZUL AZUL BLANCO-B AMARILLO AZUL AZUL BLANCO-B $
/TECLAS-DE-FUNCION 4 'Cancelar' $
/LONG. 15 25 /BN NO-E VI NO-E /CAMPOS $
'Tipo de marca' /ENC. $
0 'Cuadro' 1 'Triangulo' 2 'Flecha derecha' $
3 'Flecha arriba' 4 'Flecha abajo' 5 'Flecha izquierda' $
6 'Rombo' 7 'Asterisco' 8 'Circulo' 9 'Cruz' $
10 'Estrella' 11 'Invisible' $
TIPO-MARCA /VAR-SEL. /DESP-LEC.
*
* Dimension de la marca
*
OPCION TERMINAL AREA 34 /RENGLON /BN CI VI NO-E $
/COLOR BLANCO BLANCO NEGRO NEGRO AMARILLO CELESTE NEGRO $
/TECLAS-DE-FUNCION 4 'Cancelar' $
/MARCO /POS. 17 1 /LONG. 4 25 $
/CAMPOS 2 3 'Dimension de marca' $
3 3 DIM-MARCA /VAR. /LEC. /INF. /DESP-LEC.
*
* Color del fondo
*
OPCION TERMINAL AREA 36 /MENU 3 0 0 /MARCO /POS. 1 30 $
/COLOR AZUL AZUL BLANCO-B AMARILLO AZUL AZUL BLANCO-B $
/TECLAS-DE-FUNCION 4 'Cancelar' $
/LONG. 19 20 /BN NO-E VI NO-E /CAMPOS $
'Color del fondo' /ENC. $
0 'Negro' 1 'Azul' 2 'Verde' 3 'Celeste' 4 ' Rojo' $
5 'Magenta' 6 'Cafe' 7 'Blanco' 8 'Gris' 9 'Azul-B' $
10 'Verde-B' 11 'Celeste-B' 12 'Rojo-B' $
13 'Magenta-B' 14 'Amarillo' 15 'Blanco-B' $
COLOR-F /VAR-SEL. /DESP-LEC.
*
* Color del marco
*
OPCION TERMINAL AREA 38 /MENU 3 0 0 /MARCO /POS. 1 55 $
/COLOR AZUL AZUL BLANCO-B AMARILLO AZUL AZUL BLANCO-B $
/TECLAS-DE-FUNCION 4 'Cancelar' $
/LONG. 19 20 /BN NO-E VI NO-E /CAMPOS $
'Color del marco' /ENC. $
0 'Negro' 1 'Azul' 2 'Verde' 3 'Celeste' 4 ' Rojo' $
5 'Magenta' 6 'Cafe' 7 'Blanco' 8 'Gris' 9 'Azul-B' $
10 'Verde-B' 11 'Celeste-B' 12 'Rojo-B' $
13 'Magenta-B' 14 'Amarillo' 15 'Blanco-B' $
COLOR-M /VAR-SEL. /DESP-LEC.
*
* Area para preguntar si borra la imagen
*
OPCION TERMINAL AREA 40 /RENGLON /MARCO /POS. 19 5 $
/LONG. 3 70 /BN NORMAL VI VI $
/COLOR ROJO ROJO BLANCO /CONFIRMAR $
/CAMPOS 'se borra la imagen' SINO /VAR. /LEC. /INF.
*
* Area para preguntar si borra la marca
*
OPCION TERMINAL AREA 42 /RENGLON /MARCO /POS. 19 5 $
/LONG. 3 70 /BN NORMAL VI VI $
/COLOR ROJO ROJO BLANCO /CONFIRMAR $
/CAMPOS 'Se borra:' DES-MARCA /VAR. /ESC. $
SINO /VAR. /LEC. /INF.
*
* Revisa que mapas faltan por agregar, para ello recorre
* todos los R1 y los que sean liga a otro mapa los pasa a
* una lista, luego revisa los que NO existen o NO tienen
* imagen y los pasa a otra lista.
*
10 OPCION DISCO MAPAS INICIO-G1
TOT-MAPAS = 0
12 BUSCAR DISCO MAPAS EJECUTA 16 SEC-G1
SI TOT-MAPAS > 0 EJECUTA 14
TOT-MAPAS = 1
LEER DISCO MAPAS NUM-MAPA-VX ( 1 ) NOM-MAPA-VX ( 1 )
14 BUSCAR RECURRENTE MAPAS 1 EJECUTA 12 SIG.
LEER DISCO MAPAS NUM-MARCA OTRO-MAPA DES-MARCA
SI OTRO-MAPA = 'NO' EJECUTA 14
TOT-MAPAS = TOT-MAPAS + 1
NUM-MAPA-VX ( TOT-MAPAS ) = NUM-MARCA
MOVER DES-MARCA A NOM-MAPA-VX ( TOT-MAPAS )
EJECUTA 14
*
16 TOT-FALTA = 0
SUB = 0
18 SUB = SUB + 1
SI SUB > TOT-MAPAS EJECUTA 30
BUSCAR DISCO MAPAS EJECUTA 20 PRIN-G1 NUM-MAPA-VX ( SUB )
LEER DISCO MAPAS IMA-MAPA
SACAR PARAMETROS CARACTERES-DE-IMAGEN CAR-IMA
SI CAR-IMA > 0 EJECUTA 18
20 TOT-FALTA = TOT-FALTA + 1
NUM-MAPA-V ( TOT-FALTA ) = NUM-MAPA-VX ( TOT-MAPAS )
MOVER NOM-MAPA-VX ( TOT-MAPAS ) A NOM-MAPA-V ( TOT-FALTA )
EJECUTA 18
*
* Seleccionar opcion a realizar
*
30 OPCION TERMINAL AREA 10 /DESPLEGAR
LEER TERMINAL EJECUTA 32 OP-SEL
SI OP-SEL = 1 EJECUTA 100
SI TOT-MAPAS = 0 EJECUTA 50
SI OP-SEL = 2 EJECUTA 140
SI OP-SEL = 3 EJECUTA 170
SI OP-SEL = 4 EJECUTA 200
SI OP-SEL = 5 EJECUTA 230
SI OP-SEL = 6 EJECUTA 290
SI OP-SEL = 7 EJECUTA 230
SI OP-SEL = 8 EJECUTA 300
32 FIN
*
* No hay informacion
*
50 OPCION TERMINAL AREA 5 /DESPLEGAR /SALVAR-ANTERIORES /EMPALMAR
MOVER 'NO hay informacion agrege el mapa principal' A DESC-ERR
ESCRIBIR TERMINAL DESC-ERR
OPCION TERMINAL AREA 5 /TERMINAR
EJECUTA 10
*
* No hay informacion de marcas
*
60 OPCION DISCO MAPAS LIBERAR
OPCION TERMINAL AREA 5 /DESPLEGAR /SALVAR-ANTERIORES /EMPALMAR
MOVER 'La imagen NO tiene marcas, de agregar marca' A DESC-ERR
ESCRIBIR TERMINAL DESC-ERR
OPCION TERMINAL AREA 5 /TERMINAR
EJECUTA 10
*
******************
*
* Caso de agregar imagen de mapa, revisa primera vez
*
100 SI TOT-MAPAS > 0 EJECUTA 112
OPCION TERMINAL AREA 12 14 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR
LEER TERMINAL EJECUTA 10 NOM-MAPA
LEER TERMINAL EJECUTA 10 IMA-MAPA
OPCION TERMINAL AREA 12 14 /TERMINAR
NUM-MAPA = 1000
INSERTAR DISCO MAPAS NUM-MAPA NOM-MAPA IMA-MAPA
OPCION DISCO MAPAS LIBERAR
EJECUTA 10
*
* Si todas las marcas definidas como liga tienen mapa dar error
*
112 SI TOT-FALTA > 0 EJECUTA 120
OPCION TERMINAL AREA 5 /DESPLEGAR /SALVAR-ANTERIORES /EMPALMAR
MOVER 'NO hay imagen de mapa por agregar' A DESC-ERR
ESCRIBIR TERMINAL DESC-ERR
OPCION TERMINAL AREA 5 /TERMINAR
EJECUTA 10
*
* Desplegar los nombres de mapas para seleccionar uno
*
120 OPCION TERMINAL AREA 16 14 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR
SUB = 0
122 SUB = SUB + 1
SI SUB > TOT-FALTA EJECUTA 124
MOVER NOM-MAPA-V ( SUB ) A DESC
ESCRIBIR TERMINAL DESC
EJECUTA 122
124 LEER TERMINAL EJECUTA 10 SUB
LEER TERMINAL EJECUTA 10 IMA-MAPA
OPCION TERMINAL AREA 16 14 /TERMINAR
BUSCAR DISCO MAPAS EJECUTA 126 PRIN-G1 NUM-MAPA-V ( SUB )
ESCRIBIR DISCO MAPAS NOM-MAPA-V ( SUB ) IMA-MAPA
OPCION DISCO MAPAS LIBERAR
EJECUTA 10
126 INSERTAR DISCO MAPAS NUM-MAPA-V ( SUB ) $
NOM-MAPA-V ( SUB ) IMA-MAPA
OPCION DISCO MAPAS LIBERAR
EJECUTA 10
*
******************
*
* Caso de agregar marca, desplegar nombres de mapas
*
140 OPCION TERMINAL AREA 16 20 22 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR
SUB = 0
142 SUB = SUB + 1
SI SUB > TOT-MAPAS EJECUTA 144
MOVER NOM-MAPA-VX ( SUB ) A DESC
ESCRIBIR TERMINAL DESC
EJECUTA 142
144 LEER TERMINAL EJECUTA 10 SUB
*
* leer la descripcion y si esta ligado a otro mapa.
* Si NO esta leer numero de la marca, si SI esta poner el
* proximo numero de mapa y registrarlo sin imagen.
*
MOVER 'NO' A OTRO-MAPA
146 LEER TERMINAL EJECUTA 10 DES-MARCA OTRO-MAPA
SI OTRO-MAPA = 'SI' EJECUTA 152
148 LEER TERMINAL EJECUTA 10 /R 146 NUM-MARCA
SI NUM-MARCA > 0 Y NUM-MARCA < 1000 EJECUTA 150
ERROR 'Debe ser de 1 a 999'
EJECUTA 148
150 BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
BUSCAR RECURRENTE MAPAS 1 EJECUTA 160 SUP. NUM-MARCA
OPCION DISCO MAPAS LIBERAR
ERROR 'Marca repetida'
EJECUTA 148
152 BUSCAR DISCO MAPAS EJECUTA 990 ULTIMO-G1
LEER DISCO MAPAS NUM-MAPA
NUM-MAPA = NUM-MAPA + 1
INSERTAR DISCO MAPAS NUM-MAPA
OPCION DISCO MAPAS LIBERAR
NUM-MARCA = NUM-MAPA
*
* Marcar la imagen y guardar
*
160 BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
LEER DISCO MAPAS IMA-MAPA
OPCION DISCO MAPAS LIBERAR
ESCRIBIR TERMINAL IMA-MAPA
LEER TERMINAL EJECUTA 10 IMA-MAPA
BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
ESCRIBIR DISCO MAPAS IMA-MAPA
INSERTAR DISCO MAPAS NUM-MARCA DES-MARCA OTRO-MAPA
OPCION DISCO MAPAS LIBERAR
OPCION TERMINAL AREA 16 20 22 /TERMINAR
EJECUTA 10
*
******************
*
* Modificar imagen del mapa
*
* Desplegar los nombres de mapas para seleccionar uno
*
170 OPCION TERMINAL AREA 14 16 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR /USO-1
SUB = 0
172 SUB = SUB + 1
SI SUB > TOT-MAPAS EJECUTA 174
MOVER NOM-MAPA-VX ( SUB ) A DESC
ESCRIBIR TERMINAL DESC
EJECUTA 172
174 LEER TERMINAL EJECUTA 10 SUB
*
* Modigficar la imagen seleccionada
*
BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
LEER DISCO MAPAS IMA-MAPA
OPCION DISCO MAPAS LIBERAR
ESCRIBIR TERMINAL IMA-MAPA
LEER TERMINAL EJECUTA 10 IMA-MAPA
OPCION TERMINAL AREA 14 /PROCESADA
*
* Revisar si todas las marcas del R1 estan en la imagen
*
BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
TOT-MAR = 0
176 BUSCAR RECURRENTE MAPAS 1 EJECUTA 180 SIG.
LEER DISCO MAPAS NUM-MARCA DES-MARCA
FORMAR IMAGEN IMA-MAPA /LEER-MARCA NUM-MARCA TIPO-MARCA $
DIM-MARCA COLOR-F COLOR-M /ERROR 178
EJECUTA 176
178 TOT-MAR = TOT-MAR + 1
NUM-MARCA-V ( TOT-MAR ) = NUM-MARCA
MOVER DES-MARCA A DES-MARCA-V ( TOT-MAR )
EJECUTA 176
180 OPCION DISCO MAPAS LIBERAR
*
* Volver a marcar
*
SUBM = 0
182 SUBM = SUBM + 1
SI SUBM > TOT-MAR EJECUTA 184
OPCION TERMINAL AREA 26 /DESPLEGAR /SALVAR-ANTERIORES $
/BORRAR
NUM-MARCA = NUM-MARCA-V ( SUBM )
MOVER DES-MARCA-V ( SUBM ) A DES-MARCA
ESCRIBIR TERMINAL DES-MARCA
OPCION TERMINAL AREA 22 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR /PROCESADA
ESCRIBIR TERMINAL IMA-MAPA
LEER TERMINAL EJECUTA 10 IMA-MAPA
OPCION TERMINAL AREA 22 /TERMINAR
OPCION TERMINAL AREA 26 /TERMINAR
EJECUTA 182
*
* Actualizar
*
184 BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
ESCRIBIR DISCO MAPAS IMA-MAPA
OPCION DISCO MAPAS LIBERAR
OPCION TERMINAL AREA 14 16 /TERMINAR
EJECUTA 10
*
******************
*
* Modificar informacion de marcas
*
* Desplegar los nombres de mapas para seleccionar uno
*
200 OPCION TERMINAL AREA 16 24 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR
SUB = 0
202 SUB = SUB + 1
SI SUB > TOT-MAPAS EJECUTA 204
MOVER NOM-MAPA-VX ( SUB ) A DESC
ESCRIBIR TERMINAL DESC
EJECUTA 202
204 LEER TERMINAL EJECUTA 10 SUB
*
* Escribir la informacion a modificar
*
BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
BUSCAR RECURRENTE MAPAS 1 EJECUTA 60 SUP.
OPCION DISCO MAPAS ORD-R1 A NUM-MARCA
210 BUSCAR RECURRENTE MAPAS 1 EJECUTA 212 ORD.
LEER DISCO MAPAS DES-MARCA
ESCRIBIR TERMINAL DES-MARCA
EJECUTA 210
212 OPCION DISCO MAPAS LIBERAR
*
* Ahora leer la modificacion
*
LEER TERMINAL DES-MARCA
IND-1L = 1
TOT-CAM = 0
BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
OPCION DISCO MAPAS ORD-R1 A NUM-MARCA
214 BUSCAR RECURRENTE MAPAS 1 EJECUTA 218 ORD.
LEER DISCO MAPAS OTRO-MAPA
SI IND-1L = 0 LEER TERMINAL DES-MARCA
IND-1L = 0
SI OTRO-MAPA = 'SI' EJECUTA 216
ESCRIBIR DISCO MAPAS DES-MARCA
EJECUTA 214
*
* Si es liga a otro mapa guardar nombre
*
216 ESCRIBIR DISCO MAPAS DES-MARCA
LEER DISCO MAPAS NUM-MARCA
TOT-CAM = TOT-CAM + 1
MOVER DES-MARCA A NOM-MAPA-V ( TOT-CAM )
NUM-MAPA-V ( TOT-CAM ) = NUM-MARCA
EJECUTA 214
*
* Actualiza la descripcion de los mapas
*
218 SUB = 0
220 SUB = SUB + 1
SI SUB > TOT-CAM EJECUTA 222
BUSCAR DISCO MAPAS EJECUTA 220 PRIN-G1 NUM-MAPA-V ( SUB )
ESCRIBIR DISCO MAPAS NOM-MAPA-V ( SUB )
EJECUTA 220
222 OPCION DISCO MAPAS LIBERAR
OPCION TERMINAL AREA 16 24 /TERMINAR
EJECUTA 10
*
******************
*
* Cambiar una marca / quitar una marca
*
* Desplegar los nombres de mapas para seleccionar uno
*
230 OPCION TERMINAL AREA 16 30 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR
SUB = 0
232 SUB = SUB + 1
SI SUB > TOT-MAPAS EJECUTA 234
MOVER NOM-MAPA-VX ( SUB ) A DESC
ESCRIBIR TERMINAL DESC
EJECUTA 232
234 LEER TERMINAL EJECUTA 10 SUB
*
* Desplegar las descripciones de marca para seleccionar una
*
BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
BUSCAR RECURRENTE MAPAS 1 EJECUTA 60 SUP.
OPCION DISCO MAPAS ORD-R1 A NUM-MARCA
240 BUSCAR RECURRENTE MAPAS 1 EJECUTA 242 ORD.
LEER DISCO MAPAS DES-MARCA NUM-MARCA OTRO-MAPA
SI OTRO-MAPA = 'SI' NUM-MARCA = 0
ESCRIBIR TERMINAL DES-MARCA NUM-MARCA OTRO-MAPA
EJECUTA 240
242 OPCION DISCO MAPAS LIBERAR
LEER TERMINAL EJECUTA 10 SUBA
*
* Leer datos de la marca en la imagen
*
BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
LEER DISCO MAPAS IMA-MAPA
OPCION DISCO MAPAS ORD-R1 A NUM-MARCA
244 BUSCAR RECURRENTE MAPAS 1 EJECUTA 990 ORD.
SUBA = SUBA - 1
SI SUBA > 0 EJECUTA 244
LEER DISCO MAPAS NUM-MARCA DES-MARCA OTRO-MAPA
OPCION DISCO MAPAS LIBERAR
SI OP-SEL = 7 EJECUTA 260
FORMAR IMAGEN IMA-MAPA /LEER-MARCA NUM-MARCA TIPO-MARCA $
DIM-MARCA COLOR-F COLOR-M
*
* Seleccionar el cambio
*
OPCION TERMINAL AREA 32 34 36 38 /DESPLEGAR /SALVAR-ANTERIORES $
/BORRAR
LEER TERMINAL EJECUTA 10 TIPO-MARCA
250 LEER TERMINAL EJECUTA 10 DIM-MARCA
SI DIM-MARCA >= 3 Y DIM-MARCA <= 50 EJECUTA 252
ERROR 'Dimension no esta de 3 a 50'
EJECUTA 250
252 LEER TERMINAL EJECUTA 10 COLOR-F
LEER TERMINAL EJECUTA 10 COLOR-M
OPCION TERMINAL AREA 32 34 36 38 /TERMINAR
OPCION TERMINAL AREA 16 30 /TERMINAR
*
* Hacer el cambio
*
FORMAR IMAGEN IMA-MAPA /CAMBIAR-MARCA NUM-MARCA TIPO-MARCA $
DIM-MARCA COLOR-F COLOR-M
BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
ESCRIBIR DISCO MAPAS IMA-MAPA
OPCION DISCO MAPAS LIBERAR
EJECUTA 10
*
******************
*
* Caso de quitar la marca, revisa este ligada
*
260 SI OTRO-MAPA = 'NO' EJECUTA 262
NUM-MAPA = NUM-MARCA
BUSCAR DISCO MAPAS EJECUTA 262 PRIN-G1 NUM-MAPA
OPCION DISCO MAPAS LIBERAR
OPCION TERMINAL AREA 5 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR
MOVER 'Marca esta ligada, quite la imagen' A DESC-ERR
ESCRIBIR TERMINAL DESC-ERR
OPCION TERMINAL AREA 5 /TERMINAR
OPCION TERMINAL AREA 16 30 /TERMINAR
EJECUTA 10
*
* Preguntar si se borra
*
262 OPCION TERMINAL AREA 42 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR
ESCRIBIR TERMINAL DES-MARCA
LEER TERMINAL SINO
OPCION TERMINAL AREA 42 /TERMINAR
OPCION TERMINAL AREA 16 30 /TERMINAR
SI SINO = 'NO' EJECUTA 10
BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
LEER DISCO MAPAS IMA-MAPA
FORMAR IMAGEN IMA-MAPA /BORRAR-MARCA NUM-MARCA
ESCRIBIR DISCO MAPAS IMA-MAPA
BUSCAR RECURRENTE MAPAS 1 EJECUTA 990 SUP. NUM-MARCA
BORRAR RECURRENTE MAPAS 1
OPCION DISCO MAPAS LIBERAR
EJECUTA 10
*
******************
*
* Quitar imagen de mapa
*
* Desplegar los nombres de mapas para seleccionar uno
*
290 OPCION TERMINAL AREA 14 16 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR /USO-2
SUB = 0
292 SUB = SUB + 1
SI SUB > TOT-MAPAS EJECUTA 294
MOVER NOM-MAPA-VX ( SUB ) A DESC
ESCRIBIR TERMINAL DESC
EJECUTA 292
294 LEER TERMINAL EJECUTA 10 SUB
*
* Desplegar el mapa, revisar si tiene marcas
*
BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
LEER DISCO MAPAS IMA-MAPA
ESCRIBIR TERMINAL IMA-MAPA
BUSCAR RECURRENTE MAPAS 1 EJECUTA 296 SUP.
OPCION DISCO MAPAS LIBERAR
OPCION TERMINAL AREA 5 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR /PROCESADA /CANCELAR-CONFIRMAR
MOVER 'Imagen tiene marcas, quite las marcas' A DESC-ERR
ESCRIBIR TERMINAL DESC-ERR
OPCION TERMINAL AREA 5 /TERMINAR
OPCION TERMINAL AREA 14 16 /TERMINAR
EJECUTA 10
*
* Pregunta si la borra
*
296 OPCION DISCO MAPAS LIBERAR
OPCION TERMINAL AREA 40 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR /PROCESADA /CANCELAR-CONFIRMAR
LEER TERMINAL SINO
OPCION TERMINAL AREA 40 /TERMINAR
OPCION TERMINAL AREA 14 16 /TERMINAR
SI SINO = 'NO' EJECUTA 10
BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
BORRAR DISCO MAPAS
OPCION DISCO MAPAS LIBERAR
EJECUTA 10
*
******************
*
* Revisar, faltan imagenes
*
300 SI TOT-FALTA = 0 EJECUTA 302
OPCION TERMINAL AREA 5 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR
MOVER 'Faltan imagenes por agregar' A DESC-ERR
ESCRIBIR TERMINAL DESC-ERR
OPCION TERMINAL AREA 5 /TERMINAR
EJECUTA 10
*
* Faltan marcas
*
302 SUB = 0
304 SUB = SUB + 1
SI SUB > TOT-MAPAS EJECUTA 308
BUSCAR DISCO MAPAS EJECUTA 990 PRIN-G1 NUM-MAPA-VX ( SUB )
LEER DISCO MAPAS NOM-MAPA
BUSCAR RECURRENTE MAPAS 1 EJECUTA 306 SUP.
EJECUTA 304
306 OPCION TERMINAL AREA 5 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR
MOVER 'Imagen NO marcada' A DESC-ERR
MOVER NOM-MAPA A DESC-ERR /AGREGAR
ESCRIBIR TERMINAL DESC-ERR
OPCION TERMINAL AREA 5 /TERMINAR
EJECUTA 304
308 OPCION DISCO MAPAS LIBERAR
EJECUTA 10
*
* Error
*
990 ERROR 'Error de programa'
FIN