PROGRAMA 'Leer, Mod, ... Logos'
*
* Este programa sirve para agreagar, quitar, modificar o
* consulta del banco de datos de logos de empresas.
* Sirve para ilustrar la lectura, modificacion y
* consulta de imagenes
*
IGUAL AREA N10 NUM
OPCION TERMINAL AREA 1 /MENU /MARCO /POS. 1 10 $
/COLOR BLANCO BLANCO NEGRO NEGRO AMARILLO CELESTE NEGRO $
/TECLAS-DE-FUNCION 1 'Terminar' $
/LONG. 3 60 /BN NO-E VI NO-E /CAMPOS $
1 '*Agregar' 4 '*Quitar' 2 '*Modificar' 3 '*Consultar' $
NUM /VAR-SEL.
*
* Area para numero y nombre de la empresa
*
OPCION TERMINAL AREA 2 /RENGLON /BN CI VI NO-E $
/COLOR BLANCO BLANCO NEGRO NEGRO AMARILLO CELESTE NEGRO $
/TECLAS-DE-FUNCION 1 'Terminar' $
/MARCO /POS. 5 10 /LONG. 4 60 $
/TAB. 3 25 /INF-GLOBAL /MOD-1-GLOBAL /ESC-2-GLOBAL $
/CAMPOS NUM-EMP /LEC-1 /LEC-2 /DESP-LEC. NOM-EMP
*
* Area para leer, modificar y escribir la imagen del logo
*
OPCION TERMINAL AREA 3 /IMAGEN /BN VI $
/COLOR BLANCO BLANCO NEGRO $
/MARCO /POS. 10 15 /LONG. 11 50 $
/MOD-1-GLOBAL /ESC-2-GLOBAL /ESC-3-GLOBAL $
/TECLAS-DE-FUNCION 1 'Terminar' $
/CONFIRMAR /CONFIRMAR-1 /CONFIRMAR-2 /TIEMPO 0 0 $
/CAMPOS 2 3 'Logo:' $
2 15 LOGO-EMP /VAR. /LEC. /LONG. 18 /RENG. 9
*
* Area de pregunta en quitar
*
OPCION TERMINAL AREA 4 /RENGLON /POS. 19 5 /LONG. 3 70 $
/MARCO /COLOR ROJO ROJO BLANCO NEGRO AMARILLO $
/CAMPOS 'Es el logo a quitar' SINO /VAR. /LEC. /INF.
*
* Desplegar areas y leer lo que se va a hacer
*
1 OPCION TERMINAL AREA 1 2 3 /DESPLEGAR
LEER TERMINAL EJECUTA 50 NUM
SI NUM = 2 EJECUTA 10
SI NUM = 3 EJECUTA 20
SI NUM = 4 EJECUTA 20
*
* Caso de agregar, leer y validar numero de empresa
*
5 NUM-EMP = 1
BUSCAR DISCO LOGO EJECUTA 7 ULTIMO-G1
LEER DISCO LOGO NUM-EMP
NUM-EMP = NUM-EMP + 1
7 LEER TERMINAL EJECUTA 50 NUM-EMP
BUSCAR DISCO LOGO EJECUTA 9 PRIN-G1 NUM-EMP
ERROR 'Logo con numero' NUM-EMP 'ya existe'
EJECUTA 7
*
* Leer el nombre y las imagenes, luego insertar
*
9 LEER TERMINAL EJECUTA 50 NOM-EMP
LEER TERMINAL EJECUTA 50 LOGO-EMP
INSERTAR DISCO LOGO NUM-EMP NOM-EMP LOGO-EMP
OPCION TERMINAL AREA 1 2 3 /TERMINAR
EJECUTA 1
*
* Caso de modificacion
*
10 OPCION TERMINAL AREA 2 /INICIO-USO-1
LEER TERMINAL EJECUTA 50 NUM-EMP
BUSCAR DISCO LOGO EJECUTA 12 PRIN-G1 NUM-EMP
LEER DISCO LOGO NOM-EMP LOGO-EMP
ESCRIBIR TERMINAL NOM-EMP
LEER TERMINAL EJECUTA 50 NOM-EMP
OPCION TERMINAL AREA 3 /INICIO-USO-1
ESCRIBIR TERMINAL LOGO-EMP
LEER TERMINAL EJECUTA 50 LOGO-EMP
ESCRIBIR DISCO LOGO NOM-EMP LOGO-EMP
OPCION TERMINAL AREA 1 2 3 /TERMINAR
EJECUTA 1
12 ERROR 'Logo con numero' NUM-EMP 'no registrado'
EJECUTA 10
*
* Caso de consulta y de quitar
*
20 OPCION TERMINAL AREA 2 /INICIO-USO-2
21 LEER TERMINAL EJECUTA 50 NUM-EMP
BUSCAR DISCO LOGO EJECUTA 25 PRIN-G1 NUM-EMP
LEER DISCO LOGO NOM-EMP LOGO-EMP
ESCRIBIR TERMINAL NOM-EMP
SI NUM = 4 EJECUTA 30
OPCION TERMINAL AREA 3 /INICIO-USO-2
ESCRIBIR TERMINAL LOGO-EMP
OPCION TERMINAL AREA 1 2 3 /TERMINAR
EJECUTA 1
25 ERROR 'Logo con numero' NUM-EMP 'no registrado'
EJECUTA 21
*
* Caso de quitar, pregunta si es este ?
*
30 OPCION TERMINAL AREA 3 /INICIO-USO-3
ESCRIBIR TERMINAL LOGO-EMP
OPCION TERMINAL AREA 4 /DESPLEGAR /SALVAR-ANTERIORES $
/EMPALMAR /PROCESADA
LEER TERMINAL SINO
SI SINO = 'SI' BORRAR DISCO LOGO
OPCION TERMINAL AREA 4 /TERMINAR /INMEDIATA
OPCION TERMINAL AREA 1 2 3 /TERMINAR
EJECUTA 1
*
* Fin
*
50 FIN