PROGRAMA 'Informacion produccion'
*
* Este programa despliega un mapa y una vez que el usario
* selecciona una marca, despliega una grafica.
*
IGUAL AREA N10 REN COL RM CM SEL
*
* Definir las areas para desplegar los mapas
*
OPCION TERMINAL AREA 10 /MENU /SELECCIONAR-MARCA $
/MARCO /VARIAS-SELECCIONES /POS. 1 10 /LONG. 20 60 $
/BN VI /COLOR BLANCO-B BLANCO-B NEGRO /TIEMPO 0 0 10 $
/TECLAS-DE-FUNCION 2 'Fin/Reg' $
/CAMPOS 'Seleccione:' /ENC. $
IMA-MAPA /VAR-OP. NUM-MARCA /VAR-SEL.
*
* Area de estadisticas
*
OPCION TERMINAL AREA 12 /IMAGEN $
/LONG. 9 30 /POS. REN COL /MARCO /CONFIRMAR $
/BN VI /COLOR GRIS GRIS NEGRO /TIEMPO 0 10 $
/CAMPOS 2 2 GRAF-EST /VAR. /ESC. /ESC-1 /LONG. 28 /RENG. 7
*
* Generar la informacion de produccion en los trimestres
* ***** Usted debe poner una logica para hacerlo ******
*
TOT-PT1 = 100
TOT-PT2 = 150
TOT-PT3 = 75
TOT-PT4 = 125
*
10 BUSCAR DISCO MAPAS EJECUTA 20 SEC-G1
12 BUSCAR RECURRENTE MAPAS 1 EJECUTA 10 SIG.
LEER DISCO MAPAS OTRO-MAPA
SI OTRO-MAPA = 'SI' EJECUTA 12
ESCRIBIR DISCO MAPAS TOT-PT1 TOT-PT2 TOT-PT3 TOT-PT4
TOT-PT1 = TOT-PT1 + 10
TOT-PT2 = TOT-PT2 - 10
TOT-PT3 = TOT-PT3 + 5
TOT-PT4 = TOT-PT4 - 5
EJECUTA 12
*
**************************************************************
*
* Parte I desplegar el mapa
*
* La primera vez buscar el mapa con numero 1000.
* Si es liga entre mapas buscar el mapa con el numero de la marca
* En ambos casos agregar descripcion de las marcas
*
20 NUM-MAPA = 1000
22 BUSCAR DISCO MAPAS EJECUTA 26 PRIN-G1 NUM-MAPA
LEER DISCO MAPAS IMA-MAPA
24 BUSCAR RECURRENTE MAPAS 1 EJECUTA 30 SIG.
LEER DISCO MAPAS NUM-MARCA DES-MARCA
FORMAR IMAGEN IMA-MAPA /OPCIONES-MARCA NUM-MARCA DES-MARCA
EJECUTA 24
26 SI NUM-MAPA = 1000 $
ERROR 'Se debe ejecutar primero PSSIC1 y dar mapa 1000'
SI NUM-MAPA <> 1000 $
ERROR 'Mapas mal ligado, se puso SI en' NUM-MAPA
FIN
*
* Desplegar el mapa y leer numero de marca
*
30 OPCION TERMINAL AREA 10 /DESPLEGAR
ESCRIBIR TERMINAL IMA-MAPA
32 LEER TERMINAL EJECUTA 34 NUM-MARCA
*
* Buscar la marca en el R1, si tiene OTRO-MAPA en SI regresar
* a desplegarlo, si es NO pasar a desplegar estadisticas
*
BUSCAR RECURRENTE MAPAS 1 EJECUTA 36 SUP. NUM-MARCA
LEER DISCO MAPAS OTRO-MAPA
SI OTRO-MAPA = 'NO' EJECUTA 40
NUM-MAPA = NUM-MARCA
EJECUTA 22
*
* Dio F1 si es el mapa 1000 terminar, si no desplegarlo
* regresar a desplegarlo.
*
34 SI NUM-MAPA = 1000 FIN
EJECUTA 20
*
* Error en programas marca no esta en R1
*
36 ERROR 'Error de programa'
EJECUTA 20
*
**************************************************************
*
* Parte II Logica para desplegar la estadistica
*
40 LEER DISCO MAPAS DES-MARCA TOT-PT1 TOT-PT2 TOT-PT3 TOT-PT4
*
* Formar la grafica
*
FORMAR IMAGEN GRAF-EST /GRAFICA-BARRAS DES-MARCA /2D $
/DATO TOT-PT1 '1' 'AZUL' $
/DATO TOT-PT2 '2' 'VERDE' $
/DATO TOT-PT3 '3' 'CAFE' $
/DATO TOT-PT4 '4' 'AMARILLO' $
/CONSTRUIR
*
* Sacar renglon y columna de la marca y con ello calcular
* el renglon y columna donde se despliegan
*
SACAR PARAMETROS RENGLON-COLUMNA RM CM
* ERROR RM CM
REN = 1
COL = 1
SI RM > 10 Y CM > 40 EJECUTA 42
COL = 50
SI RM > 10 Y CM <= 40 EJECUTA 42
REN = 11
SI CM <= 40 EJECUTA 42
COL = 1
*
* Desplegar estadistica y regresar a leer otra marca
*
42 SACAR PARAMETROS SELECCIONADO SEL
SI SEL = 1 OPCION TERMINAL AREA 12 /DESPLEGAR $
/SALVAR-ANTERIORES /EMPALMAR
SI SEL = 0 OPCION TERMINAL AREA 12 /DESPLEGAR $
/SALVAR-ANTERIORES /EMPALMAR /USO-1
ESCRIBIR TERMINAL GRAF-EST
OPCION TERMINAL AREA 12 /TERMINAR
EJECUTA 32